mIRC Home    About    Download    Register    News    Help

Print Thread
#112641 25/02/05 08:10 PM
Joined: Jan 2005
Posts: 19
M
malis Offline OP
Pikka bird
OP Offline
Pikka bird
M
Joined: Jan 2005
Posts: 19
Does any one know the remote for clones so when i right click on the nick that it shows its clones if any

#112642 25/02/05 08:43 PM
Joined: Sep 2004
Posts: 237
Fjord artisan
Offline
Fjord artisan
Joined: Sep 2004
Posts: 237
Theres a ton of them... try doing a search for clones and i promise you will get more results than you will ever need. wink

#112643 25/02/05 08:52 PM
Joined: Jan 2005
Posts: 19
M
malis Offline OP
Pikka bird
OP Offline
Pikka bird
M
Joined: Jan 2005
Posts: 19
i mean when you click on someones nick dpending what script yuo have it says info,whois etc. but i want it also to show colnes there if that nick has any. I know yuo can see clones with cone scaner

#112644 25/02/05 09:10 PM
Joined: Dec 2002
Posts: 3,547
S
Hoopy frood
Offline
Hoopy frood
S
Joined: Dec 2002
Posts: 3,547
Code:
menu nicklist {
  $iif($me !isop $chan,$style(6) Scan $$1,Scan $$1): {
    if ($ial == $false) { 
      .ial on 
    } 
    if ($chan($chan).ial == $false) { 
      who $chan 
    } 
    var %x = $ialchan($address($$1,2),$chan,0)
    if ($ialchan($address($$1,2),$chan,0) >= 1) {
      echo -a There is $ialchan($address($$1,2),$chan,0) user(s) in $chan with that host.      
      while (%x) {
        inc %clones
        echo -a %clones $+ . $ialchan($address($$1,2),$chan,%x).nick ( $+ $ialchan($address($$1,2),$chan,%x).addr $+  )
        dec %x
      }
      unset %clones
    }
  }
}


There is 2 user(s) in #Andy with that host.
1. Test (andy@=KGzsab36-555-238-419.range81-155.btcentralplus.com)
2. SladeKraven (andy@=KGzsab36-555-238-419.range81-155.btcentralplus.com)

#112645 26/02/05 11:24 AM
Joined: Jan 2005
Posts: 19
M
malis Offline OP
Pikka bird
OP Offline
Pikka bird
M
Joined: Jan 2005
Posts: 19
Thank you

#112646 26/02/05 10:12 PM
Joined: Feb 2005
Posts: 185
S
Vogon poet
Offline
Vogon poet
S
Joined: Feb 2005
Posts: 185
Now i once used a pre written script which when a user join the channel ie.

[ 21:59:42 ] · · Joins :Skeletor [ Skeletor@sg-24545.ntl.com ] [Clone:Pearl ] [Last Nick: Skelatin]

I would like to incoporate that into my IRC client, The most i can do is

[ 21:59:42 ] · · Joins :Skeletor [ Skeletor@sg-24545.ntl.com ]

Now searching for clones in #Channel
Clones: Pearl & Skeletor: @sg-24545.ntl.com
Clonescan took 0 seconds.

Which is okay but i removed it because it was filling my screen with the delayed clone scanners because of the busy channel

And another thing, on *:op:*: now i also see there are on ^!:op:*: and many other types of "op" referances, how does this work?

Any ideas?


sub-zero.homeip.net:6667

#112647 27/02/05 03:48 AM
Joined: Aug 2003
Posts: 1,831
I
Hoopy frood
Offline
Hoopy frood
I
Joined: Aug 2003
Posts: 1,831
Maybe this
Code:
on *^:join:#:{
  var %i = 1,%a,%b = $gettok($hget(lastnicks,$site),1,32)
  while $ialchan($1,$2,%i).nick { %a = %a $v1 | inc %i }
  ; %a is set all nicks from $site
  if %b && $v1 != $nick { %b = [Last Nick: $v1 $+ ] } | else var %b
  ; if <lastnick> is the current nick it will not be shown
  if $remtok(%a,$nick,32) { %a = [Clones: $v1 $+ ] } | else var %a
  ; check if there are any clones to display
  echo -tic join #  · · Joins $nick $+([,$address,] %a %b
  hadd -m lastnicks $site $nick $ctime
  ; update hash table
  .timerlastnick 1 3 hsave lastnicks lastnicks.hsh
  ; save hash table, timer so it isn't saved multiple times if multiple joins
  haltdef
}
on *:nick:{
  ; Update hash table
  hadd lastnicks $site $newnick $ctime
}
on *:disconnect:{
  hsave lastnicks lastnicks.hsh
}
on *:start:{
  hmake lastnicks 10
  ; Makes table
  if $isfile(lastnicks.hsh) { hload lastnicks lastnicks.hsh }
  ; loads table entries
  var %i = 1,%a
  while $hget(lastnicks,%i).item {
    ; loop all entries
    %a = $v1
    if $gettok($hget(lastnicks,%a),2,32) < $calc($ctime - 604800) { hdel lastnicks %a }
    ; delete entries not used for more than one week - adjust 604800 for more or less time.
    inc %i
  }
  hsave lastnicks lastnicks.hsh
  ; resave the table
}

#112648 27/02/05 05:19 AM
Joined: Feb 2005
Posts: 185
S
Vogon poet
Offline
Vogon poet
S
Joined: Feb 2005
Posts: 185
No Joy,

* Invalid format: $+ (line 176,script.mrc)
* Invalid format: $+ (line 167, script.mrc)
* /hadd: no such table 'lastnicks' (line 176, Added.si2)
* Invalid format: $+ (line 167, script.mrc)


sub-zero.homeip.net:6667

#112649 27/02/05 05:39 AM
Joined: Aug 2003
Posts: 1,831
I
Hoopy frood
Offline
Hoopy frood
I
Joined: Aug 2003
Posts: 1,831
Hum sorry,
Code:
on *^:join:#:{
  var %i = 1,%a,%b = $gettok($hget(lastnicks,$site),1,32)
  while $ialchan($1,$2,%i).nick { %a = %a $v1 | inc %i }
  ; %a is set all nicks from $site
  if %b && $v1 != $nick { %b = [Last Nick: $v1 $+ ] } | else var %b
  ; if <lastnick> is the current nick it will not be shown
  if $remtok(%a,$nick,32) { %a = [Clones: $v1 $+ ] } | else var %a
  ; check if there are any clones to display
[color:blue]  echo -tic join #  · · Joins $nick $+([,$address,][color:red])[/color] %a %b[/color]
  hadd -m lastnicks $site $nick $ctime
  ; update hash table
  .timerlastnick 1 3 hsave lastnicks lastnicks.hsh
  ; save hash table, timer so it isn't saved multiple times if multiple joins
  haltdef
}
on *:nick:{
  ; Update hash table
[color:blue]  hadd [color:red]-m[/color] lastnicks $site $newnick $ctime[/color]
}
on *:disconnect:{
  hsave lastnicks lastnicks.hsh
}
on *:start:{
  hmake lastnicks 10
  ; Makes table
  if $isfile(lastnicks.hsh) { hload lastnicks lastnicks.hsh }
  ; loads table entries
  var %i = 1,%a
  while $hget(lastnicks,%i).item {
    ; loop all entries
    %a = $v1
    if $gettok($hget(lastnicks,%a),2,32) < $calc($ctime - 604800) { hdel lastnicks %a }
    ; delete entries not used for more than one week - adjust 604800 for more or less time.
    inc %i
  }
  hsave lastnicks lastnicks.hsh
  ; resave the table
}


BTW:
  • * Invalid format: $+ (line 176,script.mrc)
    * Invalid format: $+ (line 167, script.mrc)
    * /hadd: no such table 'lastnicks' (line 176, Added.si2)
    * Invalid format: $+ (line 167, script.mrc)

There is no line with both a "$+" and "hadd" in it smile

#112650 27/02/05 05:47 AM
Joined: Aug 2003
Posts: 1,831
I
Hoopy frood
Offline
Hoopy frood
I
Joined: Aug 2003
Posts: 1,831
This will only show when you select a nick that has clones in the channel.
Code:
menu nicklist {
  $iif(!$ialchan($address($$1,2),#,2),$style(2)) Clones ( $+ $ialchan($address($1,2),#,0) $+ ) :{
    var %i = 1,%a
    while $ialchan($address($1,2),#,%i).nick { %a = %a $v1 | inc %i }
    echo -eatic Info Clones from: $address($1,2) $+ : %a
  }
}

#112651 27/02/05 06:37 AM
Joined: Feb 2005
Posts: 185
S
Vogon poet
Offline
Vogon poet
S
Joined: Feb 2005
Posts: 185
Well the errors have gone, but nothing happens, i have pasted them into a Fresh .mrc file and saved all info, i then exited my IRC client, but on a new user joining, there was nothing, not a sausage

confused

Any ideas


sub-zero.homeip.net:6667

#112652 27/02/05 06:49 AM
Joined: Aug 2003
Posts: 1,831
I
Hoopy frood
Offline
Hoopy frood
I
Joined: Aug 2003
Posts: 1,831
You replied to the post about scanning from nicklist, I assume tho that you did add the other code and not the nicklist code smile

This is what it displays for me.
Addresses removed...
  • · · Joins monique [XX@--.--.--.---]
    · · Joins hoop [XX@--.--.--.com]
I don't have timestamping enabled, so no timestamp, the users had no previous nicks, nor clones. smile

Edit:Uh actually here is another line to replace
Code:
  while $ialchan($wildsite,#,%i).nick { %a = %a $v1 | inc %i }


Edit:
A join with a clone and a prior nick
  • · · Joins nick [~XX@123.123.123.123] [Clones: nic8] [Last Nick: hi18]

Last edited by Iori; 27/02/05 07:28 AM.
#112653 27/02/05 07:13 AM
Joined: Feb 2005
Posts: 185
S
Vogon poet
Offline
Vogon poet
S
Joined: Feb 2005
Posts: 185
Would the server that i am using effect it?

I even installed a fresh mIRC client and made a new .mrc file with the new code and when a new user joins there is just the std joins: blah [blah@23423.co.uk]

Nothing about clones, and this user had clones within the channel


sub-zero.homeip.net:6667

#112654 27/02/05 07:32 AM
Joined: Aug 2003
Posts: 1,831
I
Hoopy frood
Offline
Hoopy frood
I
Joined: Aug 2003
Posts: 1,831
Is "/remote on"

BTW: I made it so that it doesn't mention clones if there aren't any, same for prior nicks smile See the edit in my last post.

#112655 27/02/05 07:42 AM
Joined: Feb 2005
Posts: 185
S
Vogon poet
Offline
Vogon poet
S
Joined: Feb 2005
Posts: 185
That is as far as i gets, but so far we are making slight progress

· · Joins Skeletal [Blah@sg-63656.ntl.com] [Last Nick: Beta]


sub-zero.homeip.net:6667

#112656 27/02/05 07:53 AM
Joined: Feb 2005
Posts: 185
S
Vogon poet
Offline
Vogon poet
S
Joined: Feb 2005
Posts: 185
Right!!! thanks a million, it works lovely


sub-zero.homeip.net:6667


Link Copied to Clipboard