For whispers, you'll only need mTwitch.Core.mrc

It *does* attempt to get a list of ips/servers but if that fails it falls back to testing against known twitch servers such as: tmi.chat.twitch.tv, irc.chat.twitch.tv, irc.twitch.tv, tmi.twitch.tv

Secondly, the requirements for those scripts is using mIRC v7.43 or later and having my JSON parser loaded.


--

If instead you JUST want the whisper support you can use the following code; again, you'll need mIRC v7.43 or later. (pulled straight from mTwitch.Core.mrc and slightly edited to use literal server matching)

Code:
;; Converts incoming twitch whispers to private queries
;; Use on TEXT(/help on TEXT) or on OPEN(/help on OPEN) events to handle the event
on $*:PARSELINE:in:/^((@\S+ )?)(\x3A[^!@ ]+![^@ ]+@\S+) WHISPER (\S+) (\x3A.*)/i:{
  var %Count  = $regml(0)
  var %Tags   = $regml($calc(%Count -3))
  var %User   = $regml($calc(%Count -2))
  var %Target = $regml($calc(%Count -1))
  var %Msg    = $regml(%Count)
  if ($regex($server, /^(tmi|irc)\.(chat\.)?twitch\.tv$/i) && $me == %target) {
    .parseline -it
    .parseline -itqp %Tags %User PRIVMSG $me %Msg
  }
}

;; Converts outbound private queries into twitch whispers
on $*:PARSELINE:out:/^PRIVMSG ([^#]\S*) \x3A(.+)$/i:{
  var %Target = $regml(1)
  var %Msg    = $regml(2)
  if ($regex($server, /^(tmi|irc)\.(chat\.)?twitch\.tv$/i)) {
    .parseline -otn PRIVMSG jtv :/w $lower(%Target) %Msg
  }
}

Last edited by FroggieDaFrog; 23/06/16 07:07 AM.
I am SReject
My Stuff