/say {
;check to see if active is a DCC, use the mIRC say command if it is
if ((=* iswm $active) && ($chat($remove($active,=)) == $remove($active,=))) {
!say $1-
}
;if active window is not dcc, check to see if $1 isn't null, if it isn't, send a raw privmsg command to active window
else {
if ($1- != $null) {
raw -q PRIVMSG $active : $+ $1-
;check to see if active is a channel i'm on, and double confirm i'm on it
if (($active ischan) && ($me ison $chan)) {
;check to see if nick status for me is on (enabled in mIRC
;options), if it is, display my current status.
if ($gettok($readini($mircini,options,n0),23,44) == 1) {
echo $colour(own) -tmi $+ $len($timestamp) $active ( $+ $+ $colour(highlight) $+ $nick($chan,$me).pnick $+ $+ ) $1-
}
;check to see if nick status for me is off, if it is, it just displays
;your nickname
if ($gettok($readini($mircini,options,n0),23,44) != 1) {
echo $colour(own) -tmi $+ $len($timestamp) $active ( $+ $+ $colour(highlight) $+ $me $+ $+ ) $1-
}
}
;check to see if query is the active window,
;if it is, echo to query
if ($query($active)) {
echo $colour(own) -tmi $+ $len($timestamp) $active ( $+ $+ $colour(highlight) $+ $me $+ $+ ) $1-
}
}
}
}
/msg {
;checks to see if $1 is a DCC window, if it is, use mIRC's
;default msg command to send to DCC window
if ((=* iswm $1) && ($chat($remove($1,=)) == $remove($1,=))) {
!msg $1-
}
;check to see if $2 is not empty
;(this is the message, $1 is recipient of msg)
else {
if ($2 != $null) {
raw -q PRIVMSG $1 : $+ $2-
;checks to see if $1 is a channel, if it is,
;and i'm on it, then it echos the message into that channel, and does the same thing that the /say command
;does to check if i have status for my nick enabled
if (($1 ischan) && ($me ison $1)) {
if ($gettok($readini($mircini,options,n0),23,44) == 1) {
echo $colour(own) -tqi $+ $len($timestamp) $1 ( $+ $+ $colour(highlight) $+ $nick($chan,$me).pnick $+ $+ ) $2-
}
if ($gettok($readini($mircini,options,n0),23,44) != 1) {
echo $colour(own) -tqi $+ $len($timestamp) $1 ( $+ $+ $colour(highlight) $+ $me $+ $+ ) $2-
}
}
;checks to see if $1 is a query, if it is, echoes
;the text into the query window
if ($1 == $query($1)) {
echo $colour(own) -tqi $+ $len($timestamp) $query($1) ( $+ $+ $colour(highlight) $+ $me $+ $+ ) $2-
}
;checks to see if $1 isn't an active channel
;or isn't an active query and outputs the message into the
;active window
if (($1 !ischan) && ($1 != $query($1))) {
echo $colour(notice) -atqi $+ $len($timestamp) $str($chr(149),3) (privmsg) $+(,$chr(171),) $+(,,$1,) $2-
}
}
}
}
/amsg {
;sets a variable to 1 (because you're obviously in one channel if you're using amsg)
var %i 1
;uses $chan(0) to return total number of channels
;you're on and loops through and msgs each channel,
;incrementing %i until %i equals number of channels you're
;on, and stops.
;it also echoes into the right channels.
while (%i <= $chan(0)) {
.msg $chan(%i) $1-
echo -tqmi $+ $len($timestamp) $chan(%i) ( $+ $+ $colour(highlight) $+ $nick($chan(%i),$me).pnick $+ $+ ) $1-
inc %i
}
}
