Forums Bug Reports typing space using font Terminal is not monospaced

unit Unit1;

interface

uses
  Winapi.Windows,
  Winapi.Messages,
  System.SysUtils,
  System.Variants,
  System.Classes,
  Vcl.Graphics,
  Vcl.Controls,
  Vcl.Forms,
  Vcl.Dialogs,
  Vcl.StdCtrls,
  Vcl.ComCtrls;

type
  TRichEdit = class(Vcl.ComCtrls.TRichEdit)
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  end;

  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    RichEdit1: TRichEdit;
    Memo1: TMemo;
    Button5: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

uses
  RichEdit;

procedure TRichEdit.CreateParams(var Params: TCreateParams);
const
  RICHEDIT_CLASS = 'RICHEDIT50W';  RICHEDIT_LIBRARY = 'msftedit.dll';
  // RICHEDIT_CLASS = 'RICHEDIT20W';  RICHEDIT_LIBRARY = 'riched20.dll';

begin
  if LoadLibrary(RICHEDIT_LIBRARY) = 0 then
    RaiseLastOSError;

  inherited CreateParams(Params);
  CreateSubClass(Params, RICHEDIT_CLASS);
end;

procedure DumpCharFormat(Handle: HWND; const Caption: string);
var
  CF: CHARFORMAT2W;
begin
  ZeroMemory(@CF, SizeOf(CF));
  CF.cbSize := SizeOf(CF);

  SendMessageW(Handle, EM_GETCHARFORMAT, SCF_SELECTION, LPARAM(@CF));

  Form1.Memo1.Lines.Add(Caption);
  Form1.Memo1.Lines.Add('  FaceName: ' + PWideChar(@CF.szFaceName));
  Form1.Memo1.Lines.Add('  Charset: ' + inttostr(CF.bCharSet));
  Form1.Memo1.Lines.Add('  PitchAndFamily: ' + inttostr(CF.bPitchAndFamily));
  Form1.Memo1.Lines.Add('  Height: ' + inttostr(CF.yHeight));
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  RichEdit1.Font.Name := 'terminal';
  RichEdit1.Font.Size := 14;
  RichEdit1.Font.Charset := OEM_CHARSET;
  DumpCharFormat(RichEdit1.Handle, 'Before typing');
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  DumpCharFormat(RichEdit1.Handle, 'After typing');
end;

procedure TForm1.Button5Click(Sender: TObject);
var
  CF: CHARFORMAT2W;
begin
  FillChar(CF, SizeOf(CF), 0);
  CF.cbSize := SizeOf(CF);
  CF.dwMask := CFM_FACE or CFM_CHARSET;
  CF.bCharSet := OEM_CHARSET;
  StringToWideChar('Terminal', CF.szFaceName, LF_FACESIZE);

  SendMessage(RichEdit1.Handle, EM_SETCHARFORMAT, SCF_ALL, LPARAM(@CF));
  DumpCharFormat(RichEdit1.Handle, 'after charset');
end;

end.