alias sockget {
if (!$1-) { echo -a ERROR: Enter the URL Page correctly! | return }
; example: /sockget http://mirc.com/versions.txt
var %s = sockget_ $+ $rand(1,100000)
if ($sock(%s)) { sockclose %s }
var %site = $1-
var %get_host = $chr(47) $+ $gettok(%site,3-,47)
var %host = $gettok(%site,2,47)
if ($right(%site,1) == $chr(47)) && ($right(%get_host,1) !== $chr(47)) { var -s %get_host = %get_host $+ $chr(47) }
if (*https* iswm %site) { sockopen -e %s %host 443 }
else { sockopen %s %host 80 }
sockmark %s %get_host
}
ON *:SOCKOPEN:sockget_*: {
if ($sockerr) { echo -a ERROR: SOCKOPEN -> $sock($sockname).wserr -> $sock($sockname).wsmsg | return }
sockwrite -n $sockname GET $sock($sockname).mark HTTP/1.0
sockwrite -n $sockname Host: $sock($sockname).addr
sockwrite -n $sockname User-Agent: */*
sockwrite -n $sockname Connection: Close
sockwrite -n $sockname
}
ON *:SOCKREAD:sockget_*: {
if ($sockerr) { echo -a ERROR: SOCKREAD -> $sock($sockname).wserr -> $sock($sockname).wsmsg | return }
var %read
sockread %read
if ($sockbr) { echo -ag READ: $left(%read,4096) }
}
ON *:SOCKCLOSE:sockget_*: { echo -ag SOCKET CONNECTION CLOSED! }