Forums Scripts & Popups Trying to properly split a text entry

.hadd -m Items Rome $addtok($hget(Items,Rome),black pistol,44)
.hadd -m Items Saudi_Arabia $addtok($hget(Items,Saudi_Arabia),black pistol,44)
.hadd -m Items Sweden $addtok($hget(Items,Sweden),black pistol,44)
.hadd -m Items Rome $addtok($hget(Items,Rome),machine gun,44)
.hadd -m Items Saudi_Arabia $addtok($hget(Items,Saudi_Arabia),machine gun,44)
.hadd -m Items Sweden $addtok($hget(Items,Sweden),machine gun,44)

alias addtest {

  var %string = Rome, "Saudi Arabia", Sweden black pistol, machine gun

  var %n = 1, %locations, %items
  ; loop comma-delimited tokens, tokenize the token
  while ($gettok(%string,%n,44)) {
    var %token = $v1
    tokenize 32 %token
    ; looping "locations" so far
    if (!%items) {
      ; token is no quote, and token contains a space char: split token found.
      if (%token == $noqt(%token)) && ($2) {
        ; first part of split token belongs to "locations", second part to "items"
        var %locations = $addtok(%locations,$1,44)
        var %items = $2-
      }
      ; it's not yet the split token: add this token to "locations" and remove possible quotes
      else { var %locations = $addtok(%locations,$noqt($1-),44) }
    }
    ; already looping "items": add this token to "items"
    else { var %items = $addtok(%items,$1-,44) }
    inc %n
  }
  ECHO -a locations: %locations
  ECHO -a items: %items
}

split_text {
  ; Usage: /split_text <formatted string>
  ; eg. /split_text Rome, "Saudi Arabia", Sweden black pistol, machine gun
  var %input = $regsubex($1-, /\s*\x2c\s*/g, $chr(44))
  %input = $regsubex(%input, /(?<=^|\x2c)(?:(\w+)|"([^"]+)")\s+([^\x2c]+)/, $+(\1,$cr,\2))
  var %cities = $gettok(%input, 1, 13), %weapons = $gettok(%input, 2, 13), %weapon
  var %i = $numtok(%cities, 44), %weaponcount = $numtok(%weapons, 44), %city
  while %i {
    %city = $replace($noqt($gettok(%cities, %i, 44)), $chr(32), _)
    %j = 1
    while %j <= %weaponcount {
      %weapon = $gettok(%weapons, %j, 44)
      .hadd -m Items %city $addtok($hget(Items, %city), %weapon, 44)
      inc %j
    }
    dec %i
  }
}

; !add <locations separated by comma> : <items separated by comma>
; (the $gettok($v1,1-,32) will remove leading/trailing spaces of locations/items)

on *:text:!add *:#: {
  tokenize 58 $2-
  var %n = 1
  while ($gettok($1,%n,44)) {
    var %location = $replace($gettok($v1,1-,32),$chr(32),_), %x = 1
    while ($gettok($$2-,%x,44)) {
      hadd -m items %location $addtok($hget(items,%location),$gettok($v1,1-,32),44)
      inc %x
    }
    inc %n
  }
}