Forums Bug Reports $comval inefficiency and bug

alias mirclinks {
  var %t
  .comopen ie.main internetexplorer.application
  showmirc -s
  %t = $com(ie.main,navigate,1,bstr*,http://www.mirc.com/get.html)
  :loop
  %t = $ticks + 300
  while ($ticks < %t) !
  %t = $com(ie.main,readystate,2)
  if ($com(ie.main).result != 4) goto loop
  %t = $com(ie.main,document,2,dispatch* ie.doc)
  %t = $com(ie.doc,links,2,dispatch* ie.links)
 
  var %total = $comval(ie.links,0), %ticks, %i
  echo -ac info Total amount of links: %total
  echo -a $chr(15)

  echo -ac info * Looping with $!comval from 1 - %total
  %ticks = $ticks
  %i = 1
  while (%i <= %total) {
    %t = $comval(ie.links,%i,href)
    inc %i
  }
  echo -ac info * Time taken with first approach: $calc($ticks - %ticks) ms
  echo -a $chr(15)
  echo -ac info * Looping with $!comval from %total - 1
  %ticks = $ticks
  %i = %total
  while (%i) {
    %t = $comval(ie.links,%i,href)
    dec %i
  }
  echo -ac info * Time taken with second approach: $calc($ticks - %ticks) ms
  echo -a $chr(15)
  echo -ac info * Looping with item method to access the collection 
  %ticks = $ticks
  %i = 0
  while (%i < %total) {
    %t = $com(ie.links,item,1,uint,%i,dispatch* ie.item)
    if ($com(ie.item)) {
      %t = $com(ie.item,href,2)
      %t = $com(ie.item).result
      .comclose ie.item
    }
    inc %i
  }
  echo -ac info * Time taken with third approach: $calc($ticks - %ticks) ms
  :error
  if ($com(ie.links)) .comclose $v1
  if ($com(ie.doc)) .comclose $v1
  if ($com(ie.main)) .comclose $v1 $com($v1,close,1)
}

alias shellwindows {
  var %t, %i = 0, %total
  .comopen shell shell.application
  %t = $com(shell,windows,3,dispatch* wins)
  %t = $com(wins,count,3)
  %total = $com(wins).result

  echo -a Total amount of shell windows found: %total
  echo -a But what does comval say? -> $comval(wins,0)

  echo -a Trying to access this collection with the "item" method:

  while (%i < %total) {
    %t = $com(wins,item,1,uint,%i,dispatch* item)
    if ($com(item)) {
      echo -a Item %i retrieved with dispatch
      .comclose item
    }
    inc %i
  }

  echo -a Using VBScript to access the collection:

  window -h @@
  %t = aline @@

  %t dim s
  %t set shell = createobject("shell.application")
  %t set wins = shell.windows
  %t For each item in wins
  %t s = s & item.locationurl & VbCrLf
  %t Next
  %t wscript.echo s

  savebuf @@ wins.vbs
  close -@ @@
  run wins.vbs
  .timer 1 2 .remove wins.vbs
  :error
  if ($com(shell)) .comclose $v1
  if ($com(wins)) .comclose $v1
}