Forums Scripts & Popups Tasks

alias listprocesses {
  echo -ae Listing running processes...
  tokenize 32 listprocesses $+ $ticks Error!
  .comopen $1tmpa WbemScripting.SWbemLocator
  if $comerr { echo 4 -a $2 | goto end }
  .comclose $1tmpa $com($1tmpa,ConnectServer,3,dispatch* $1tmpb)
  if $com($1tmpb) { .comclose $v1 $com($v1,ExecQuery,1,bstr*,SELECT $&
    name $+ $chr(44) $+ executablepath FROM win32_process,dispatch* $1) }
  if !$com($1) { echo 4 -a $2 | goto end }
  var %i = 1, %a = $comval($1,0)
  while %i <= %a {
    echo -a $comval($1,%i,name) ( $+ $comval($1,%i,executablepath) $+ )
    inc %i
  }
  .comclose $1
  :end
  echo -ae Finished listing running processes.
}

alias closeprocess {
  tokenize 32 closeprocess $+ $ticks $int($1) $remove($2-,")
  if $2 !isnum 0- || $3 == $null { echo -cei info * /closeprocess: invalid parameters | halt }
  .comopen $1tmpa WbemScripting.SWbemLocator
  if $comerr { echo -cei info * /closeprocess: COM error | halt }
  .comclose $1tmpa $com($1tmpa,ConnectServer,1,dispatch* $1tmpb)
  if $com($1tmpb) { .comclose $v1 $com($v1,ExecQuery,1,bstr*,SELECT name $&
    FROM win32_process WHERE name=' $+ $3-',dispatch* $1) }
  if !$com($1) { echo -cei info * /closeprocess: COM error | halt }
  if !$2 {
    var %i = $comval($1,0)
    while %i {
      !.echo -q $comval($1,%i,terminate)
      dec %i
    }
  }
  else !.echo -q $comval($1,$2,terminate)
  .comclose $1
}