Forums Scripts & Popups $address not working correctly

/*
* KICKBAN selected users from the userlist
* in the active channel window, with optional reason,
* taking care of webchat users,
* collecting upto four channel modes in a single line,
* and de-opping chanops
*
*/
alias kbchan {
  if (($me !isop #) && ($me !ishop #)) {
    return
  }

  var %snick = $snick(#, 0)
  var %banstr
  var %cmdstr
  var %sign
  var %fix

  while (%snick > 0) {
    if (%fix != $null) {
      %cmdstr = +b
      %banstr = %fix
      %sign = +
    }

    ; Deop if opped
    if ($snick(#, %snick) isop #) {
      %cmdstr = %cmdstr $+ -o
      %banstr = %banstr $snick(#, %snick)
      if (%sign != -) { %sign = - }
    }
    elseif ($snick(#, %snick) ishop #) {
      %cmdstr = %cmdstr $+ -h
      %banstr = %banstr $snick(#, %snick)
      if (%sign != -) { %sign = - }
    }

    ; Ban
    if (html.chat isin $address($snick(#, %snick), 4)) {
      %fix = $remove($address($snick(#, %snick), 3), .html.chat)
    }
    elseif (mibbit.com isin $address($snick(#, %snick), 4)) {
      %fix = $remove($address($snick(#, %snick), 3), .mibbit.com)
    }
    else {
      %fix = $address($snick(#, %snick), 2)
    }

    if ($len($remove(%cmdstr,+,-)) < 4) {
      if (%sign != +) {
        %cmdstr = %cmdstr $+ +
        %sign = +
      }
      %cmdstr = %cmdstr $+ b
      %banstr = %banstr %fix
      %fix = $null
    }

    dec %snick
    if (($len($remove(%cmdstr,+,-)) < 4) && (%snick > 0)) {
      continue
    }

    mode # %cmdstr %banstr

    %cmdstr = $null
    %banstr = $null
    %sign = $null
  }
  if (%fix != $null) {
    mode # +b %fix
  }

  ; Kick
  %snick = $snick(#, 0)
  while (%snick > 0) {
    kick # $snick(#, %snick) $1-
    dec %snick
  }
}