Actually, the first one will work for anyone conditional that the bot has ops. The @ character only checks for the ops status of the client running the code.
Code:
on *:text:!allow*:#:{
  if $nick !isop $chan {
    .notice $nick Insufficient access. Ops status required
  }
  elseif !$2 {
    .notice $nick Insufficient parameters. One or more nicks required
  }
  else {
    var %nicks = $replace($2-,$chr(44),$chr(32))
    var %a = 1, %b = $numtok(%nicks,32)
    while %a <= %b {
      .hadd -m Allowed $gettok(%nicks,%a,32) $addtok($hget(Allowed,$gettok(%nicks,%a,32)),$chan,32)
      inc %a
    }
  }
}
on @*:text:!invite*:#:{
  if !$2 {
    .notice $nick  Insufficient parameters. One or more nicks required
  }
  else {
    var %nicks = $replace($2-,$chr(44),$chr(32))
    var %a = 1, %b = $numtok(%nicks,32)
    while %a <= %b {
      if $istok($hget(Allowed,$gettok(%nicks,%a,32)),$chan,32) {
        invite $gettok(%nicks,%a,32) $chan
      }
      inc %a
    }
  }
}
on *:text:!disallow*:#:{
  if $nick !isop $chan {
    .notice $nick Insufficient access. Ops status required
  }
  elseif !$2 {
    .notice $nick Insufficient parameters. One or more nicks required
  }
  else {
    var %nicks = $replace($2-,$chr(44),$chr(32))
    var %a = 1, %b = $numtok(%nicks,32)
    while %a <= %b {
      .hadd -m Allowed $gettok(%nicks,%a,32) $remtok($hget(Allowed,$gettok(%nicks,%a,32)),$chan,1,32)
      inc %a
    }
  }
}
on *:start:{
  if !$hget(Allowed) { .hmake Allowed 100 }
  if $exists(Allowed.hsh) { .hload Allowed Allowed.hsh }
}
on *:exit:{
  .hsave -o Allowed Allowed.hsh
}
on *:disconnect:{
  .hsave -o Allowed Allowed.hsh
}


Requires Ops status to add nicks with !allow or remove them with !disallow. Notices going out if the person doesn't have ops or if there are no nicks specified.
Multiple nicks can be specified, separated by comma or space.

Works in multiple rooms on a single network, and on multiple networks conditional that no two rooms on two networks have identical names.

Nicks & channels stored in hash table while bot is connected.