Heh, you're right again, thanks for the fix! Since that code is in there 3 times and needs to be changed only 2 times, it's still nearly fried my brains smile

I did consider wether I'd add days first or months first, I knew there would be differences, but ofcourse I forgot that when I was comparing our scripts crazy

About the leap year stuff: I just looked at the tests and missed all required tests. Well, I actually looked at your script and wondered why my leap day test was 5 times longer smile I didn't consider then that it doesn't matter for your script since $ctime can't reach 1900 or 2100 anyways crazy

I found some more bugs too, and this time they're in my script frown frown Boundary problems where a time would be like 12:00:60 and such. And a regex problem where anything lacking seconds wouldn't be matched.

Final version, I could make the normal date format regex more allowing for missing hour, but letters are beginning to dance before my eyes...
(lotsa code, again frown )
Code:
; Return duration in years/months/days starting from a specific date and a duration in
; (one, more or all of) years/months/weeks/days/hours/minutes/seconds
; usage: $datediff3(25/12/2002 10:35:00,1yr 252wks 15mths 60days 25hrs 61secs,past,nsw)
; use past for having a duration to something that's in the past and future for something in the future
; use now as date for using the current date.
; nsw -> see switches of $datediff
alias datediff3 return $datediff($1,$datediff2($1,$2,$3,$4),$4)

; Return the date something happened or will happen based on start date and duration

; usage: $datediff3(25/12/2002 10:35:00,1yr 252wks 15mths 60days 25hrs 61secs,past)
; use past for having a duration to something that's in the past and future for something in the future
; use now as date for using the current date.
; use u as 4th parameter only for mm/dd/yyy hh:nn:ss style dates
alias datediff2 {
  var %1 = $iif($1 == now,$date(dd/mm/yyyy hh:nn:ss),$1) , %2 = $$2
  if ($regex(%1,/^0*(\d+)\D0*(\d+)\D(\d+)\D0*(\d+)\D0*(\d+)\D0*(\d+)(?:\D?([ap]\.?m\.?|noon|midday|midnight))?$/i)) {
    var %d1 = $regml($iif(u isin $4,2,1)), %m1 = $regml($iif(u isin $4,1,2))
    var %h1 = $regml(4), %n1 = $regml(5), %s1 = $regml(6), %y1 = $regml(3)
    if ((%h1 == 12) && (($regml(7) == am) || ($v1 == midnight))) var %h1 = 0
    elseif ((%h1 isnum 1-11) && ($regml(7) == pm)) inc %h1 12
  }
  if ((%m1 !isnum 1-12) || (%d1 !isnum 1-31) || (%h1 !isnum 0-23) || (%m1 !isnum 0-59) || (%s1 !isnum 0-59)) return Date invalid


  if ($regex(%2,/^(?:(\d+) *y\w* *|())(?:(\d+) *mo?n?ths? *|())(?:(\d+) *w\w* *|())(?:(\d+) *d\w* *|()) $+ $&
    (?:(\d+) *h\w* *|())(?:(\d+) *mi\w* *|())(?:(\d+) *s\w*|()) *$/i)) {
    var %y = $calc($regml(1)), %m = $calc($regml(2)), %d = $calc(7 * $calc($regml(3)) + $calc($regml(4)))
    var %h = $calc($regml(5)), %n = $calc($regml(6)), %s = $calc($regml(7))
  }
  else return invalid duration given...

  if ($3 == future) {
    var %s2 = %s1 + %s
    while (%s2 > 59) var %s2 = %s2 - 60, %n = %n + 1
    var %n2 = %n1 + %n
    while (%n2 > 59) var %n2 = %n2 - 60, %h = %h + 1
    var %h2 = %h1 + %h
    while (%h2 > 23) var %h2 = %h2 - 24, %d = %d + 1
    var %m2 = %m1 + %m
    while (%m2 > 12) var %m2 = %m2 - 12, %y = %y + 1
    var %y2 = %y1 + %y, %d2 = %d1 + %d
    while (%d2 > $gettok(31 $iif((!$calc(%y2 % 400)) || (($calc(%y2 % 100)) && (!$calc(%y2 % 4))),29,28) 31 30 31 30 31 31 30 31 30 31,%m2,32)) {
      var %d2 = %d2 - $v2, %m2 = %m2 + 1
      if (%m2 > 12) var %m2 = %m2 - 12, %y2 = %y2 + 1
    }
  }
  elseif ($3 == past) {
    var %s2 = %s1 - %s
    while (%s2 < 0) var %s2 = %s2 + 60, %n = %n - 1
    var %n2 = %n1 - %n
    while (%n2 < 0) var %n2 = %n2 + 60, %h = %h - 1
    var %h2 = %h1 - %h
    while (%h2 < 0) var %h2 = %h2 + 24, %d = %d - 1
    var %m2 = %m1 - %m
    while (%m2 < 1) var %m2 = %m2 + 12, %y = %y - 1
    var %y2 = %y1 - %y, %d2 = %d1 - %d
    while (%d2 < 1) {
      var %d2 = %d2 + $gettok(31 31 $iif((!$calc(%y2 % 400)) || (($calc(%y2 % 100)) && (!$calc(%y2 % 4))),29,28) 31 30 31 30 31 31 30 31 30,%m2,32)
      var %m2 = %m2 - 1 | if (%m2 < 1) var %m2 = %m2 + 12, %y2 = %y2 - 1
    }
  }
  else return uhm, you want the third parameter to be future or past...
  if (u isin $4) return $+($base(%m2,10,10,2),/,$base(%d2,10,10,2),/,$base(%y2,10,10,4) $base(%h2,10,10,2),:,$base(%n2,10,10,2),:,$base(%s2,10,10,2))
  return $+($base(%d2,10,10,2),/,$base(%m2,10,10,2),/,$base(%y2,10,10,4) $base(%h2,10,10,2),:,$base(%n2,10,10,2),:,$base(%s2,10,10,2))
}

alias datediff {
  ; calculate difference between date 1 and date 2, in years,months,(weeks),days,hours,minutes,seconds
  ; usage $datediff(dd/mm/yyyy HH:nn:ss, dd/mm/yyyy HH:nn:ss)
  ; meaning $datediff($date $time, $date $time)
  ; example:  //echo -a $datediff(3/5/2005 20:00:10, 5/10/2000 12:15:20)
  ; ** IMPORTANT: $date uses dd/mm/yyyy, if you want to input mm/dd/yyyy style, 
  ; **   add a third parameter 'u'
  ; other parameters
  ;  w = use weeks
  ;  a = display all fields, also 0 values
  ;  s = short duration identifiers
  ;  n = no spaces between numbers and durations
  ;  d = only numbers, no durations (use 'a' too or you won't have a clue what it means ;)
  ;  z = zeropad fields years(4) months(2) weeks(1) days(1) hours(2) minutes(2) seconds(2)
  ; example:  //echo -a $datediff(1/5/2005 11:15:22pm, 1/8/2005 12:15:22P.M., uws)
  ; hh:nn:ss am/pm is supported (only now I realize how strange it actually is)
  ; my reference: http://www.worldtimezone.com/wtz-names/wtz-am-pm.html

  var %1 = $1, %2 = $2, %switched = $false
  :dateswitch
  if ($regex(%2,/^0*(\d+)\D0*(\d+)\D(\d+)\D0*(\d+)\D0*(\d+)\D0*(\d+)(?:\D?([ap]\.?m\.?|noon|midday|midnight))?$/i)) {
    var %d1 = $regml($iif(u isin $3,2,1)), %m1 = $regml($iif(u isin $3,1,2))
    var %h1 = $regml(4), %n1 = $regml(5), %s1 = $regml(6), %y1 = $regml(3)
    if ((%h1 == 12) && (($regml(7) == am) || ($v1 == midnight))) var %h1 = 0
    elseif ((%h1 isnum 1-11) && ($regml(7) == pm)) inc %h1 12
  }
  else return Date 1 in incorrect format
  if ($regex(%1,/^0*(\d+)\D0*(\d+)\D(\d+)\D0*(\d+)\D0*(\d+)\D0*(\d+)(?:\D?([ap]\.?m\.?|noon|midday|midnight))?$/i)) {
    var %d2 = $regml($iif(u isin $3,2,1)), %m2 = $regml($iif(u isin $3,1,2))
    var %h2 = $regml(4), %n2 = $regml(5), %s2 = $regml(6), %y2 = $regml(3)
    if ((%h2 == 12) && (($regml(7) == am) || ($v1 == midnight))) var %h2 = 0
    elseif ((%h2 isnum 1-11) && ($regml(7) == pm)) inc %h2 12
  }
  else return Date 2 in incorrect format
  if ((%m1 !isnum 1-12) || (%d1 !isnum 1-31) || (%h1 !isnum 0-23) || (%m1 !isnum 0-59) $&
    || (%s1 !isnum 0-59)) return Date 1 invalid ( %y1 ; %m1 ; %d1 ; %h1 ; %n1 ; %s1 )
  if ((%m2 !isnum 1-12) || (%d2 !isnum 1-31) || (%h2 !isnum 0-23) || (%m2 !isnum 0-59) $&
    || (%s2 !isnum 0-59)) return Date 2 invalid
  var %s = %s1 - %s2 | if (%s < 0) var %s = %s + 60, %n1 = %n1 - 1
  var %n = %n1 - %n2 | if (%n < 0) var %n = %n + 60, %h1 = %h1 - 1
  var %h = %h1 - %h2 | if (%h < 0) var %h = %h + 24, %d1 = %d1 - 1
  var %d = %d1 - %d2
  if (%d < 0) var %d = %d + $gettok(31 31 $iif((!$calc(%y1 % 400)) || (($calc(%y1 % 100)) $&
    && (!$calc(%y1 % 4))),29,28) 31 30 31 30 31 31 30 31 30,%m1,32), %m1 = %m1 - 1
  var %m = %m1 - %m2, %y = %y1 - %y2, %w
  if (%m < 0) var %m = %m + 12, %y = %y - 1
  if (%y < 0) { if (%switched) return ERROR | var %1 = $2, %2 = $1, %switched = $true | goto dateswitch }

  if ( w  isin $3) var %w = $int($calc(%d / 7)) weeks, %d = $calc(%d - 7 * %w)
  if ( z  isin $3) var %y = $base(%y,10,10,4), %m = $base(%m,10,10,2), %d = $base(%d,10,10,2), $&
    %h = $base(%h,10,10,2), %n = $base(%n,10,10,2), %s = $base(%s,10,10,2)
  var %res = %y years %m months %w %d days %h hours %n minutes %s seconds
  if ((a !isin $3) && ( $regsub(%res,/(?<!\d)0 \w++/g,,%res) )) { }
  if ( s  isin $3) { var %res = $replace(%res,year,yr,month,mth,week,wk,hour,hr,minute,min,second,sec) }
  $null($regsub(%res,/(?<!\d)(1 \w+)s(?!\w)/g,\1,%res))
  if ((n  isin $3) && ( $regsub(%res,/(?<=\d)\s+(?=\w)/g,,%res) )) { }
  if ((d  isin $3) && ( $regsub(%res,/\w/g,,%res) )) { }
  return %res
}