1. You are using both * and 1 (both are access level choices) - just use one or the other: 1 if you don't use any named levels or * if you do.
  2. You are not giving the on TEXT a target to check in: * (both query and any channel), ? (just in a query), # (only in any channel) or #namedChannel (just in that one channel or channel list).
  3. You are not leaving a space after the { and before the msg command: {msg or {/msg will not work.
  4. Your { starts on the next line but if (condition) requires it to be on the same line as the if for a multi-lined code block.
  5. Unless you want to check the same line for each possible condition, use elseif for the following conditional checks.
  6. Your final iswm is misspelled.
  7. Your final msg command has no target ($chan) to send the message to.
Code:

on *:TEXT:*:#:{
  if (*i like dogs* iswm $1-) msg $chan cats are better
  elseif (*how are you* iswm $1-) msg $chan im great, and you?
  elseif (*how old are you?* iswm $1-) msg $chan 20
  elseif (*!TEST* iswm $1-) msg $chan this is just a auto-response test
  elseif (*Here's a hint* iswm $1-) msg $chan afk
}

Or, if you prefer a multi-lined format:
Code:

on *:TEXT:*:#:{
  if *i like dogs* iswm $1- {
    msg $chan cats are better
  }
  elseif *how are you* iswm $1- {
    msg $chan im great, and you?
  }
  elseif *how old are you?* iswm $1- {
    msg $chan 20
  }
  elseif *!TEST* iswm $1- {
    msg $chan this is just a auto-response test
  }
  elseif *Here's a hint* iswm $1- {
    msg $chan afk
  }
}

Or even:
Code:

on *:TEXT:*:#:{
  if *i like dogs* iswm $1- {
    msg $chan cats are better
  } | elseif *how are you* iswm $1- {
    msg $chan im great, and you?
  } | elseif *how old are you?* iswm $1- {
    msg $chan 20
  } | elseif *!TEST* iswm $1- {
    msg $chan this is just a auto-response test
  } | elseif *Here's a hint* iswm $1- {
    msg $chan afk
  }
}