how do I stop the same raw from doing both command

Print Thread

#124683 09/07/05 09:13 PM

Joined: May 2005

Posts: 30

Zedrick

Ameglian cow

Zedrick

Ameglian cow

Joined: May 2005

Posts: 30

I have 2 things with the same raw number 302 (/userhost) for different things and the raw is doing both commands.

How do I stop the raw from doing both commands to only do that command for that one only and the other command for the other one which it is doing both ?

Code:


on OP:TEXT:KILL *:?:{
  userhost $2
  kline $2 $3-
  kill $2 [ $+ $nick $+ ] $3-
  .timerUNKLINE 1 3600 unkline $2 
}

raw 302:*:.timerKILL 1 3 kill $gettok($2,2,64))

------------------------------------------------------
------------------------------------------------------

on OP:TEXT:ROOMBAN *:?:{ 
  set $+(%,rb.nick,$$3) $3
  set $+(%,rb.chan,$3) $$2
  set $+(%,rb.reason,$3) $4-
  userhost $3
  .timerROOMBAN-NOTICE 1 2 .notice $3  $+ $3  $+ - you have been removed from $2 by  $+ $nick  $+ for being of - $4-
  wallops $nick ROOMBAN $2 $3 for 1 hour for being of - $4- 
}

raw 302:*:{ var %n = $($+(%,rb.nick,$gettok($2,1,61)),2),%c = $($+(%,rb.chan,%n),2)
  if ($gettok($2,1,61) == %n) { mode %c +b $+(*!*@,$gettok($2,2,64))
    kick %c %n $($+(%,rb.reason,%n),2)
    unset %rb.*
    .timer-b 1 3600 mode %c -b $+(*!*@,$gettok($2,2,64)) 
  }
}

Re: how do I stop the same raw from doing both command

#124684 09/07/05 09:52 PM

xhine

i would probably set vars.. like so:

Code:



on OP:TEXT:KILL *:?:{
  set %kill $true
  timer 1 2 set %kill $false
  ;You can UNSET too if you dont wanna make it $false
  userhost $2
  kline $2 $3-
  kill $2 [ $+ $nick $+ ] $3-
  .timerUNKLINE 1 3600 unkline $2 
}
on OP:TEXT:ROOMBAN *:?:{ 
  set %roomban $true
  timer 1 2 set %roomban $false
  ;You can UNSET too if you dont wanna make it $false
  set $+(%,rb.nick,$$3) $3
  set $+(%,rb.chan,$3) $$2
  set $+(%,rb.reason,$3) $4-
  userhost $3
  .timerROOMBAN-NOTICE 1 2 .notice $3  $+ $3  $+ - you have been removed from $2 by  $+ $nick  $+ for being of - $4-
  wallops $nick ROOMBAN $2 $3 for 1 hour for being of - $4- 
}
raw 302:*:{
  if (%kill) { .timerKILL 1 3 kill $gettok($2,2,64)) } 
  elseif (%roomban) {
    var %n = $($+(%,rb.nick,$gettok($2,1,61)),2),%c = $($+(%,rb.chan,%n),2)
    if ($gettok($2,1,61) == %n) { mode %c +b $+(*!*@,$gettok($2,2,64))
      kick %c %n $($+(%,rb.reason,%n),2)
      unset %rb.*
      .timer-b 1 3600 mode %c -b $+(*!*@,$gettok($2,2,64)) 
    }
  }
}

Last edited by xhine; 09/07/05 09:54 PM.

Re: how do I stop the same raw from doing both command #124685 09/07/05 10:46 PM
Joined: May 2005 Posts: 30 Z Zedrick OP Ameglian cow
OP Zedrick Ameglian cow Z Joined: May 2005 Posts: 30	Hi xhine it has worked, thank you with the kill, it kills the person first with the reason and then it kills all of the person's connections on their !@host with no reason. How can I kill all of the connections with the reason ?

Re: how do I stop the same raw from doing both command

#124686 10/07/05 11:39 PM

xhine

i am assuming that $3- is the reason..

Code:

 
on OP:TEXT:KILL *:?:{
  set %kill $true
  set %kill.reason $3-
  timer 1 2 set %kill $false
  ;You can UNSET too if you dont wanna make it $false
  userhost $2
  kline $2 %kill.reason
  kill $2 [ $+ $nick $+ ] %kill.reason
  .timerUNKLINE 1 3600 unkline $2 
}
on OP:TEXT:ROOMBAN *:?:{ 
  set %roomban $true
  timer 1 2 set %roomban $false
  ;You can UNSET too if you dont wanna make it $false
  set $+(%,rb.nick,$$3) $3
  set $+(%,rb.chan,$3) $$2
  set $+(%,rb.reason,$3) $4-
  userhost $3
  .timerROOMBAN-NOTICE 1 2 .notice $3  $+ $3  $+ - you have been removed from $2 by  $+ $nick  $+ for being of - $4-
  wallops $nick ROOMBAN $2 $3 for 1 hour for being of - $4- 
}
raw 302:*:{
  if (%kill) { .timerKILL 1 3 kill $gettok($2,2,64) %kill.reason } 
  elseif (%roomban) {
    var %n = $($+(%,rb.nick,$gettok($2,1,61)),2),%c = $($+(%,rb.chan,%n),2)
    if ($gettok($2,1,61) == %n) { mode %c +b $+(*!*@,$gettok($2,2,64))
      kick %c %n $($+(%,rb.reason,%n),2)
      unset %rb.*
      .timer-b 1 3600 mode %c -b $+(*!*@,$gettok($2,2,64)) 
    }
  }
}

Re: how do I stop the same raw from doing both command #124687 11/07/05 12:38 AM
Joined: May 2005 Posts: 30 Z Zedrick OP Ameglian cow
OP Zedrick Ameglian cow Z Joined: May 2005 Posts: 30	everything all works, thank you

Link Copied to Clipboard

Forums Scripts & Popups how do I stop the same raw from doing both command