Forums Scripts & Popups [HELP] !checkin script for tournaments

on $*:text:/!check(in|ed|out|clear)/Si:#: { 
  var %command $regml(1)
  var %file checkins.ini
  if (%command == in) { 
    var %team $$2
    writeini %file %team $nick 1
    msg # Checked $nick in to team %team
  }
  elseif (%command == out) { 
    var %team $$2 
    if (!$readini(%file,%team,$nick)) msg # You're currently not checked in to team %team $+ . | return
    remini %file %team $nick
  }
  elseif (%command == ed) {
    var %teams $ini(%file,0) 
    msg # There are %teams teams entered. 
    var %i 1 
    while (%i <= %teams) { 
      var %l 1
      var %team $ini(%file,%i)
      var %members $ini(%file,%team,0)
      while (%l <= %members) { 
        var %member $ini(%file,%team,%l)
        var %teammembers $addtok(%teammembers,%member,32)
        inc %l
      }
      msg # Team: %team - %teammembers
      inc %i
      unset %teammembers
    }
  }
  elseif (%command == clear) {
    remove %file 
    msg # Cleared all checkins. 
  }
}