After messing with this a bit, I got a nicklist menu set up so I can just right click to check if someone's following and it pops up in chat as well. I'll share that if anyone wants it... Just right click a username and do "Followcheck" obviously.

Code:
menu nicklist {
  Followcheck:/followcheck $1
}


alias followcheck {
  var %follow $1
  var %username $iif($left($2,1) == $chr(35),$right($2,-1),$2)
  var %url $+(https://api.twitch.tv/kraken/users/,%follow,/follows/channels/,%username)

  jsonclearcache
  var %error $json(%url,error) 
  if !%error { 
    msg # %follow is following %username  
  }
  else { 
    msg # %follow is not following %username  
  }
}


Anyway, I have a question that isn't necessarily related to this exact problem. But rather than finding an old thread to bump or creating a new one I figured I'd ask here. Is it possible to use this as a way to welcome a new follower in the chat itself? The script I currently have doesn't seem to work.

Here's what I have that is SUPPOSED to welcome new followers...

Code:
on $*:text:!followers:#: {
  followers.update -s # 
}

alias followers.update {
  if (-* iswm $1) {
    var %switches = $1
    tokenize 32 $2-
  }
  var %chan = #$$1, %limit = $iif($2,$2,25), %offset = $iif($3,$3,0)
  var %sockname = twitch.followers. $+ $ticks
  hfree -w %sockname | hmake %sockname
  hadd %sockname chan %chan
  hadd %sockname limit %limit
  hadd %sockname offset %offset
  hadd %sockname request /kraken/channels/ $+ $mid(%chan,2-) $+ /follows?limit= $+ %limit $+ &offset= $+ %offset
  hadd %sockname method GET
  hadd %sockname signal followers.update
  if (s isin %switches) hadd %sockname show 1
  if (!$hget(followers. $+ %chan)) hadd %sockname init 1
  sockopen -e %sockname api.twitch.tv 443
  return %sockname
}

on *:signal:followers.update:{
  var %err = $1, %sockname = $2, %header = $3, %data = $4
  var %chan = $hget(%sockname,chan), %init = $hget(%sockname,init), %show = $hget(%sockname,show)

  if (* 200 OK iswm $read(%header,n,1)) {
    if (!$hget(followers. $+ %chan)) {
      hmake -s followers. $+ %chan $iif($calc($json(%data,_total) / 10) > 100,$v1,$v2)
      if ($ini(followers.ini,%chan,0) > 0) hload -i followers. $+ %chan followers.ini %chan
    }

    var %i = 0, %n = $json(%data,follows).count, %new.count
    while (%i < %n) {
      var %name = $json(%data,follows,%i,user,name)
      var %display_name = $json(%data,follows,%i,user,display_name)
      if (!$hget(followers. $+ %chan,%name)) {
        hadd followers. $+ %chan %name 1
        if (!%init) && (%show) {
          set -nz %followers. $+ %chan %followers. [ $+ [ %chan ] ] %display_name
          if ($calc($len(%followers. [ $+ [ %chan ] ]) + $len(%display_name)) > 350) {
            var %msg = Welcome to our new follower $+ $iif($numtok(%followers. [ $+ [ %chan ] ],32) > 1,s:,:) $regsubex(%followers. [ $+ [ %chan ] ],/( $+ $chr(32) $+ )/g,$iif(\n == \0,$iif(\0 > 2,$chr(44),$chr(32)) and $chr(32),$chr(44) $+ $chr(32))) $+ !
            .timer 1 $iif(%flood.protection,$v1,0) msg %chan $safe(%msg)
            inc -z %flood.protection 5
            unset %followers. [ $+ [ %chan ] ]
          }
        }
        inc %new.count
      }
      else break
      inc %i
    }

    if (%new.count == $hget(%sockname,limit)) {
      followers.update %chan 100 $calc($hget(%sockname,limit) + $hget(%sockname,offset))
      var %next = $result
      if (%init) hadd %next init 1
      if (%show) hadd %next show 1
    }
    else {
      if (!%init) && (%show) && (%new.count) {
        var %msg = Welcome to our new follower $+ $iif($numtok(%followers. [ $+ [ %chan ] ],32) > 1,s:,:) $regsubex(%followers. [ $+ [ %chan ] ],/( $+ $chr(32) $+ )/g,$iif(\n == \0,$iif(\0 > 2,$chr(44),$chr(32)) and $chr(32),$chr(44) $+ $chr(32))) $+ !
        .timer 1 $iif(%flood.protection,$v1,0) msg %chan $safe(%msg)
        inc -z %flood.protection 5
      }  
      unset %followers. [ $+ [ %chan ] ]
      if ($hget(followers. $+ %chan)) hsave -i followers. $+ %chan followers.ini %chan
    }
  }

  hfree -w %sockname
  if ($isfile(%header)) .remove %header
  if ($isfile(%data)) .remove %data
}



Any help is appreciated (as always) I've been working at getting better with mIRC and reading /help just about every day. But I can't seem to find where something is wrong in this.