How do you know it was getting up to that line but not past it?

I rewrote a bit:

Code:
alias demo {
  var %user = $$1, %chan = $2, %sockname = demo. $+ $ticks
  hfree -w %sockname | hmake %sockname
  hadd %sockname user %user
  hadd %sockname chan %chan
  hadd %sockname host api.twitch.tv
  hadd %sockname port 443
  hadd %sockname request /kraken/users/ $+ %user $+ /follows/channels/k3mistvideo
  sockopen -e %sockname $hget(%sockname,host) $hget(%sockname,port)
}

on *:text:!test:#:{
  demo $nick #
}

on *:sockopen:demo.*: {
  var %<< = sockwrite -nt $sockname
  %<< GET $hget($sockname,request) HTTP/1.0
  %<< Host: $sock($sockname).addr
  %<< $crlf
}

on *:sockread:demo.*: {
  var %header, %content
  if (!$hget($sockname,header.complete)) {
    sockread %header
    while (%header != $null) {
      if (HTTP/* 2?? * iswm %header) { hadd $sockname following $true }
      elseif (HTTP/* 4?? * iswm %header) { hadd $sockname following $false }
      ;echo -ag %header
      sockread %header
    }
    if ($sockbr) hadd $sockname header.complete $true
  }

  if ($hget($sockname,header.complete)) {
    while ($sockbr) {
      sockread -f %content
      ;if (%content != $null) echo -ag %content
    }
  }
}

on *:sockclose:demo.*:{
  if ($hget($sockname,following)) { var %msg = Following }
  else { var %msg = Not following }
  
  if ($hget($sockname,chan)) { msg $v1 %msg }
  else { echo -ag %msg }
  
  hfree $sockname
}