Paste this code into an empty file and type /jack

The aliases txt.jack and txt.old.jack are emulating what the actual text files would return. (Except old jack he's just returning the old exp values).

Right click in the @Window and sort the different columns. Edit the exp vaules in the txt.jack aliases if you need clearer examples.

Code:
alias jack {
  if (!$window(@UK_Tool)) { 
    window -lk0 -t12,42,52,62,77 @UK_Tool "Courier New" 14
    titlebar @UK_Tool - Data Comparison
  }
  if (!$window(@UK_values)) window -lh @UK_values
  else clear @UK_values
  buffer.jack  
  var %x 1 , %nexp 0 , %oexp 0 , %dexp 0 , %prexp 0 , %n , %r
  while ($txt.jack(%x)) {
    tokenize 9 $ifmatch
    %n = $gettok($gettok($1,1,40),-1,32)
    %r = $1
    %nexp = $2
    %oexp = $txt.old.jack(%x)
    %dexp = $calc(%nexp - %oexp)
    %prexp = $calc((%dexp / %oexp) * 100)
    aline @UK_Tool %r $chr(9) %n $chr(9) %oexp $chr(9) %nexp $chr(9) $iif(%oexp,%dexp,0) $chr(9) %prexp
    aline @UK_values %r $chr(9) %n $chr(9) %oexp $chr(9) %nexp $chr(9) $iif(%oexp,%dexp,0) $chr(9) %prexp
    inc %x
  }
  set %UK_win_sort -ne
}

alias txt.jack {
  if ($1 == 1) return Nemesis taian (110:80) $chr(9) 886692
  elseif ($1 == 2) return Zeus reas0nabledoubts (46:45) $chr(9) 928188
  elseif ($1 == 3) return Atlas Firewall (67:100) $chr(9) 709911
  elseif ($1 == 4) return Atlas ziming (183:57) $chr(9) 705795
  elseif ($1 == 5) return Atlas oley (80:60) $chr(9) 711597
  else return
}

alias txt.old.jack {
  if ($1 == 1) return 826692
  elseif ($1 == 2) return 728188
  elseif ($1 == 3) return 708911
  elseif ($1 == 4) return 701795
  elseif ($1 == 5) return 671597
  else return
}

alias buffer.jack {
  clear @UK_tool
  aline @UK_Tool $chr(160)
  aline @UK_Tool Rank $chr(9) User $chr(9) Old Exp $chr(9) New Exp $chr(9) Exp Gained $chr(9)  $+ $chr(37) $+ Change
  aline @UK_Tool $chr(160)
}

alias sort.jack {
  var %m 0 , %i , %t %UK_win_sort
  if ($findtok(-ra -us -oe -ne -ge -pr,%t,1,32)) { 
    %i = $v1 | %m = -tz $+ $iif(%i > 2,ue) %i 9
  }
  else return
  buffer.jack
  filter %m @UK_values @UK_Tool
}

menu @UK_Tool {
  Sort by..
  .$iif(%UK_win_sort == -pr,$style(1)) $+($chr(37),Change):set %UK_win_sort -pr | sort.jack
  .-
  .$iif(%UK_win_sort == -oe,$style(1)) Old Exp:set %UK_win_sort -oe | sort.jack
  .$iif(%UK_win_sort == -ne,$style(1)) New Exp:set %UK_win_sort -ne | sort.jack
  .$iif(%UK_win_sort == -ge,$style(1)) Gained Exp:set %UK_win_sort -ge | sort.jack
  .-
  .$iif(%UK_win_sort == -ra,$style(1)) Rank:set %UK_win_sort -ra | sort.jack
  .$iif(%UK_win_sort == -us,$style(1)) User:set %UK_win_sort -us | sort.jack
}