Hm, to capture the highlighted parts of:
<a href="/title/tt0847163/" onclick="(new Image()).src='/rg/find-title-1/title_exact/images/b.gif?link=/title/tt0847163/';">Family Guy</a> (2006) (VG) </td></tr></table> </p> <p>

I played with:
Code:
  var %line = <a href="/title/tt0847163/" onclick="(new Image()).src='/rg/find-title-1/title_exact/images/b.gif?link=/title/tt0847163/';">Family Guy</a> (2006) (VG) </td></tr></table> </p> <p>
  var %reg = /<a href="\/title\/tt(\d+)\/" onclick=".+\/title_exact.+\?link=\/title\/tt(\d+)\/';">([^<]+)</a>/i
  if ($regex(%line,%reg)){ echo -a 1st linkN: $regml(1) 2nd linkN: $regml(2) Title: $regml(3)

Result: 1st linkN: 0847163 2nd linkN: 0847163 Title: Family Guy

The second capture may or may not be redundant...
I don't know what you mean with "multiple" matches though - All the "exact matches", and if, with or without the "(2006) (VG) in the Family Guy example?


____ EDIT:

Managed to get the individual "popular" and "exact matches" with this snippet, but it's pretty ugly (especially the whiles):

Code:
; /socktest <search string>

alias socktest {
  if ($sock(imdb)) sockclose imdb
  sockopen imdb imdb.com 80
  sockmark imdb $replace($$1-,$chr(32),$(%20,0))
  .timer 1 10 sockclose imdb
}

on *:sockopen:imdb: {
  sockwrite -n $sockname get $+(/find?q=,$sock($sockname).mark,;s=tt) HTTP/1.0
  sockwrite -n $sockname Host: www.imdb.com
  sockwrite $sockname $crlf
}

on *:sockread:imdb: {
  if ($sockerr) { echo -a error | return }
  var %read
  sockread %read
  if ($gettok(%read,1-2,32) == <p><b>Popular Titles</b>) { 

    var %reg = /\/find-title-(\d+)\/title_popular\/images\/b.gif\?link=\/title\/tt(\d+)\/';">(.+?)(?=<br>|<\/td>)/gi
    noop $regex(imdb,%read,%reg)
    if ($regml(imdb,1)) ECHO -a POPULAR MATCHES
    var %n = 1
    while ($regml(imdb,%n)) {
      ECHO -a No.: $regml(imdb,%n) LinkNo: $regml(imdb,$calc(%n +1)) $&
        Text: $regsubex( $regsubex($regml(imdb,$calc(%n +2)),/<.+?>/g,$null) ,/&#(\d+);/g,$chr(\1))
      inc %n 3
    }

    var %reg = /\/find-title-(\d+)\/title_exact\/images\/b.gif\?link=\/title\/tt(\d+)\/';">(.+?)(?=<br>|<\/td>)/gi
    noop $regex(imdb,%read,%reg)
    if ($regml(imdb,1)) ECHO -a EXACT MATCHES
    var %n = 1
    while ($regml(imdb,%n)) {
      ECHO -a No.: $regml(imdb,%n) LinkNo: $regml(imdb,$calc(%n +1)) $&
        Text: $regsubex( $regsubex($regml(imdb,$calc(%n +2)),/<.+?>/g,$null) ,/&#(\d+);/g,$chr(\1))
      inc %n 3
    }
    sockclose imdb
  }
}

Hope it's a step in the right direction smile
I'd display the exact matches (if any), followed by the popular matches (if any)...

Note that this snippet doesn't use binvars - but you'll need them, and I assume the script already uses 'em. More or less results will be cut off else.

(The regsubex strip html codes in the "text" part and convert to ascii)