Try this script:

Code:

alias -l _mnick return main_nickname
alias -l _anick return alt_nickname
alias -l _mpass return main_password
alias -l _mserv return irc.server.net 6667

alias -l _ghost msg nickserv ghost $_mnick $_mpass
alias -l _mident msg nickserv identify $_mpass

on *:START:{
  mnick $_mnick
  anick $_anick
  server $_mserv
}

on *:CONNECT:{
  if ($me != $_mnick) {
    .notify $_mnick
    set -u60 %_ghost 0
  }
  if ($me == $_mnick) .timermnick 1 5 _mident
}

on *:NICK:{
  if ($newnick == $_mnick) .timermnick 1 5 _mident
}

on ^*:NOTIFY:{
  if ($nick == $_mnick) {
    haltdef
    if (%_ghost < 3) {
      inc -u60 %_ghost
      _ghost
      .timerghost 1 10 notify
    }
    else echo 4 -at Unable to GHOST $_mnick
  }
}

on ^*:UNOTIFY:{
  if ($nick == $_mnick) { 
    haltdef
    .notify -r $_mnick
    nick $_mnick
    unset %_ghost
    .timerghost off
  }
}


When loading the script, click "NO" when asked to run initialization routines.


Change main_nickname for your main registered nickname.
Change alt_nickname to an unregistered alternate nickname.
Change main_password to the password for your main registered nickname.
Change irc.server.net to the actual server (and port) that you want to connect to when mIRC opens.

You have to restart mIRC after loading the script and setting the above variables.

-genius_at_work