you looking for a script that kick on repeats ?
Code:
on @*:text:*:#: {
  if ( %rep_tid == $null ) { set %rep_tid 60 }
  if ( %rep_ban == $null ) { set %rep_ban 120 }
  if ( %rep_antal == $null ) { set %rep_antal 3 }
  if ($nick == null) { return }
  var %rp.repeats = rp. $+ $nick $+ . $+ $chan
  var %rp.text = rp. $+ $nick $+ . $+ $chan $+ .text
  if ( % [ $+ [ %rp.repeats ] ] == $null ) {
    set -u [ $+ [ %rep_tid ] ] % [ $+ [ %rp.repeats ] ] 1
    set -u [ $+ [ %rep_tid ] ] % [ $+ [ %rp.text ] ] $1-
  }
  elseif ( % [ $+ [ %rp.text ] ] == $1- ) {
    inc % [ $+ [ %rp.repeats ] ]
  }
  elseif ( % [ $+ [ %rp.text ] ] != $1- ) {
    set -u [ $+ [ %rep_tid ] ] % [ $+ [ %rp.text ] ] $1-
    set -u [ $+ [ %rep_tid ] ] % [ $+ [ %rp.repeats ] ] 1
  }
  if ( % [ $+ [ %rp.repeats ] ] >= %rep_antal ) {
    kick # $nick % [ $+ [ %rp.repeats ] ] repeats in %rep_tid second(s) Banned for $calc(%rep_ban / 60)) $+ minute(s)
    ban -u $+ %rep_ban # $nick %bs
    unset %rp. $+ $nick $+ . $+ $chan
    unset %rp. $+ $nick $+ . $+ $chan $+ . $+ text
  }
}


set %rep_tid xx <- repeat rate. default is set to 1 minute

set %rep_ban xx <- set how long the script should ban the user. default 2 minutes.

set %rep_antal xx <- set how many repeats a user is allowed to do.

everything is calced in seconds, so you need to use the value 60 for 1 minute .. 120 for two minutes and so on. And the script will ban for repeats, if you dont want that, coment out the line:

ban -u $+ %rep_ban # $nick 3

just add a ; infront of it and ur done, but then you maybe want to change the kick message.

and the code goes in to a clean remote file, ALT + R in your mirc, then create a new file and paste the code in to it.

If you want to be able to enable/disable it, then use a group for it:

#repeatkick on
code here
#repeatkick end

enable it with /enable #repeatkick
or disable it with: /disable #repeatkick

Last edited by sparta; 07/11/07 08:45 PM.