k, to elaborate on my previous post here's the complete script which should give u a start (not at home so can't test it).

Code:
raw 319:*:{
  ; check if follow toggle is on
  if (%following == 1) {

    ; create tokenized string of channels (space seperated)
    set %massjoin.string $sorttok($3-,32,c)

    ; toggle following to off so your next normal whois will be treated as a normal whois
    set %following 0

    ; set a timer (massjoin) to run for X times every 2 secs, where X = number of channels in tokenized string. Perform alias /massjoin.next
    .timermassjoin $numtok(%massjoin.string, 32) 2 /massjoin.next
    haltdef

    ; you should use this if check  with the haltdef in all whois replies if u want the entire whois hidden when doing a follow
    ; now the haltdef will only hide the channel reply
  }
}

alias massjoin.next {
  ; join first channel in tokenized string of channels (space seperated)
  join $gettok(%massjoin.string, 1, 32)

  ; remove first channel in tokenized string of channels (space seperated)
  %massjoin.string = $deltok(%massjoin.string, 1, 32)

  ; unset the now useless var %massjoin.string (i usually do this to keep my existing var list small, it's not really necessary)
  if ($numtok(%massjoin.string, 32) == 0) { unset %massjoin.string }
}

alias follow {
  ; toggle following to on
  set %following 1

  ; perform whois on target
  whois $1
}

; the comments make it long but i might have made a syntax mistake somewhere,
;   so i thought it was better to tell what each line should do so you can rectify any mistakes made
;
; I'm not sure what will happen if you perform a second /follow <target> while the first is still in action,
;   it will probably fail due to wrong variable values