I'm sure you meant /dialog -t edituser New dialog title goes here.

Perhaps you might want to show us the offending code. Here's a quickie example of doing what you said, using the nicks in the channel #mIRC to cycle through (just for content).
Code:

alias edituser dialog -m edituser tdefEditUser
dialog tdefEditUser {
  title "User List Editor:"
  size -1 -1 102 42
  option dbu
  text "User name:", 1001, 3 6 28 6, right
  edit "", 1002, 33 4 65 10, autohs disable
  text "Level:", 1003, 3 16 28 6, right
  edit "", 1004, 33 14 65 10, autohs disable
  button "&Previous", 1005, 3 26 30 12, disable
  button "&Next", 1006, 36 26 30 12
  button "Done", 1007, 68 26 30 12, ok
}
on *:DIALOG:edituser:init:{
  did -f $dname 1002
}
on *:DIALOG:edituser:sclick:1006:{
  if ($did(1002).text ison #mIRC) var %x = $nick(#mIRC, $ifmatch)
  else var %x = 0
  inc %x
  if %x <= $nick(#mIRC, 0) {
    did -ra $dname 1002 $nick(#mIRC, %x)
    dialog -t $dname Edit User - $nick(#mIRC, %x)
    did -e $dname 1002,1004
    echo $color(info) -esbflirt * Now editing user: $gettok($dialog($dname).title, 4, 32)
    if %x > 1 did -e $dname 1005
    if %x == $nick(#mIRC, 0) did -b $dname 1006
    did -f $dname 1004
  }
}
on *:DIALOG:edituser:sclick:1005:{
  if ($did(1002).text ison #mIRC) var %x = $nick(#mIRC, $ifmatch)
  else var %x
  dec %x
  if %x > 0 {
    did -ra $dname 1002 $nick(#mIRC, %x)
    dialog -t $dname Edit User - $nick(#mIRC, %x)
    echo $color(info) -esbflirt * Now editing user: $gettok($dialog($dname).title, 4, 32)
    if %x == 1 did -b $dname 1005
    if %x == $calc($nick(#mIRC, 0) - 1) did -e $dname 1006
    did -f $dname 1003
  }
}

/edituser works fine for me.

DALnet: #HelpDesk and #m[color:#FF0000]IR[color:#EEEE00]C