Forums mIRC Help how to disable /part message truncation?

[color:#840017]

on ^*:PART:#:{
  
  var %msg                         | ; Holds the formatted part string
  var %reason                      | ; Possibly holds the part reason
  var %nick = $nick                | ; Holds the Nick and possibly the (userid@site)
  var %action = echo $color(part)  | ; Holds the echo command to use (with or without -s)
  
  ;  Get the correct value to use later on: channel event, default event or none
  ;
  var %event = $gettok($readini($mircini, events, $chan), 2, 44)
  if (%event == $null) $&
    %event = $gettok($readini($mircini, events, default), 2, 44)
  if (%event == $null) $&
    %event = 0
  
  ;  Format the reason like normal for placement later
  ;
  if ($1) $&
    %reason = ( $+ $1- $+ )
  
  ;  [ ] Show addresses
  ;
  if ($gettok($readini($mircini, Options, n2), 19, 44)) $&
    %nick = %nick ( $+ $address $+ )
  
  ;  [ ] Show short joins/parts
  ;
  if ($gettok($readini($mircini, Options, n0), 2, 44)) $&
    %msg = * Parts: %nick %reason
  else $&
    %msg = * %nick has left $chan %reason
  
  ;  Determine where to place the message (if anywhere)
  ;    * [ Events ] button for default event
  ;    * Alt-minus -> Events for channel event
  ;    * Channel event event overrules default event
  ;    * If both are missing, entries go to the channel
  ;
  ;    0 = Channel
  ;    1 = Status Window
  ;    2 = Hide
  ;
  if (%event == 1) $&
    %action -sti %msg
  elseif (%event == 0) $&
    %action -ti $chan %msg
  
  haltdef
  
}[/color]