Forums Scripts & Popups HTML Scraper

alias -l hsh { return $qt($scriptdirforum_zybez.hsh) }
alias -l hsh_save { 
  if ($hget(forum_zybez)) { hsave forum_zybez $hsh }
}
alias -l hsh_load {
  if ($isfile($hsh)) {
    if (!$hget(forum_zybez)) { hmake forum_zybez 100 }
    hload forum_zybez $hsh
  }
}

alias check_new_threads {
  if (!$hget(forum_zybez)) { inc %forum_zybez_firstrun }
  sockopen forum_zybez forums.zybez.net 80
  sockmark forum_zybez /forum/354-clan-fights/
  if ($1 isnum 1-) { .timer 1 $1 check_new_threads $1 }
}
alias post_to_channel {
  var %threadid = $gettok($1-,1,9), %threadurl = $gettok($1-,2,9), %threadtitle = $gettok($1-,3,9)
  msg #yourchannel Thread ID: %threadid - URL: %threadurl - Title: %threadtitle
}

on *:sockopen:forum_zybez:{
  if ($sockerr) { echo -a * ERROR reading forum.zybez.net: $sock($sockname).wsmsg ( $+ $sock($sockname).wserr $+ ) }
  else {
    var %s = sockwrite -n $sockname
    %s GET $sock($sockname).mark HTTP/1.1
    %s Host: $sock($sockname).ip
    %s Accept: */*, *.*
    %s Connection: close
    %s
  }
}
on *:sockread:forum_zybez:{
  var %data
  sockread %data
  if ($regex(%data,/<a itemprop="url" id="(.+?)" href="(.+?)" title='(.+?)' class='topic_title' >/)) { 
    if (!$hget(forum_zybez,$regml(1))) { 
      hadd -m forum_zybez $regml(1) $+($regml(2),$chr(9),$regml(3)) 
      if (!%forum_zybez_firstrun) { post_to_channel $+($regml(1),$chr(9),$regml(2),$chr(9),$regml(3)) }
    }
  }
}
on *:sockclose:forum_zybez:{ unset %forum_zybez_firstrun }
on *:start:{ hsh_load }
on *:exit:{ hsh_save }