more questions on customizing display...

Code:

 
on ^*:NOTICE:*:#:{
  echo -m #  14[14 $+ $time(hh:nntt) $+ 14] 7*3 - $+ $nick $+ -15 $1-
  haltdef
}

First of all...I can't get that to work...

Second..what would be the remote for the topic? (when you join a channel, where it says "topic is 'blah blah' " set by nick at date.

Thanks.

Your code works for me.

i cant get it to work no matter what i do. is there another way to go about it that might work?

The reason it may not be working is that you've made an event for channel notices (/notice #chan), so if you're testing it with a regular /notice <nick> command it's not going to show.

And secondly, for the topic there are two different events.
When you join, raw 332 is triggered, but when the topic is changed, an on TOPIC event is triggered
If it's the raw event you're looking for, the "topic set by:" information is also triggered, which is raw 333

Code:

 
on ^*:NOTICE:*:?:{
  echo -m #  14[14 $+ $time(hh:nntt) $+ 14] 7*3 - $+ $nick $+ - $1-
  haltdef
}

ok, this works but echos everything to status window...
this always confuses me (when something echos to status window)...

IT could be echoing to the status window because you're using "on ^*:NOTICE:*:?: {" and defining # as the target for the echo.

Try using:

Code:

on ^*:NOTICE:*:*: {
  echo -ma 14[14 $+ $time(hh:nntt) $+ 14] 7*3 - $+ $nick $+ - $1-
  haltdef
}

This will cover all NOTICE events and echo it to the active window.

ok, i got ti to work now, but i dont want it in the currently active window....i want it to display in whatever channel I and whoever notices me are on, or atleast a channel on the server we are both on...

Code:

on ^*:NOTICE:*:*: {
  if ($me ison $chan) &amp;&amp; ($nick ison $chan) {  
    echo -ma $chan 14[14 $+ $time(hh:nntt) $+ 14] 7*3 - $+ $nick $+ - $1-  
    haltdef
  }
}

Maybe?

that one works, but it shows the notice in the default way, not in my colors/format....

Code:

on ^*:NOTICE:*:*: {
  if ($target ischan) { scid $cid echo -t $chan - $+ $nick $+ : $chan $+ - $1- | halt }
  if ($query($nick)) { scid $cid echo -t $nick - $+ $nick $+ - $1- | halt }
  else { scid $cid echo -t $comchan($nick,1) - $+ $nick $+ - $1- | halt }
}

This will display channel notices in the channel, private notices will either be displayed in the query window or the first common channel if a query window isn't available. Just modify the code the way you want it.

OK, I have the notices working fine...but the raw commands on the topic confuse me.

Code:

raw 332:*:{
  echo -a $chan 14[14 $+ $time(hh:nntt) $+ 14] 7* Topic is ' $+ $1- $+ '
  halt
}

raw 333:*:{
  echo -a $chan 14[14 $+ $time(hh:nntt) $+ 14] 7* $1- 
  halt
}

this returns:

[04:09pm] * Topic is 'MyNick #Channel Topic'
[04:09pm] * MyNick Channel TopicSettersNick 1057336873

??????

In raws, $1 is your nick, $2 is the channel (target of an event), $3- is the data.

Code:

raw 332:*:{ 
  echo $2 14[14 $+ $time(hh:nntt) $+ 14] 7* Topic is ' $+ $3- $+ '
  halt
}

raw 333:*:{ 
  echo $2 14[14 $+ $time(hh:nntt) $+ 14] 7* Set by $3 on $asctime($4)
  halt
}