Mass voice script - mIRC Discussion Forums

I want my bot to make every one who doesnt have a rank be voiced when i type .v I want it so only i can use this command. Please help me tyvm.

Code:

alias m {
  var %x = $nick($1,0,r) | while (%x) { 
    var %r = %r $nick($1,%x,r)
    if ($numtok(%r,32) = $modespl) { mode $1 + $+ $str(v,$modespl) %r | unset %r } | dec %x
  }
  if (%r) { mode $1 + $+ $str(v,$numtok(%r,32)) %r }
}

The above code goes into the remote, will voice everyone at once, skip those who are already voiced, and only you can do the voicing.

The syntax is: /m #YourChannelNameHere

You can also put this little command in your popups Nick List for an easier access via right click on the nicklist: MassVoice:m $chan

thankyou verry much

the above script isnt working can anyone help?

Can you elaborate why isn't working for you? What have you done?

alias m {
var %x = $nick($1,0,r) | while (%x) {
var %r = %r $nick($1,%x,r)
if ($numtok(%r,32) = $modespl) { mode $1 + $+ $str(v,$modespl) %r | unset %r } | dec %x
}
if (%r) { mode $1 + $+ $str(v,$numtok(%r,32)) %r }
}

I paste this into my remote, now where does the rest of the stuff go, can you please explain it a bit more detailed for someone who is new to mIRC.

Now you either type this command in your main mirc chat screen while inside your own chat room to voice those unvoiced people:

Code:

/m <Your Channel Name>

For example: /m #MyChat

Or

Code:

MassVoice:m $chan

<- This goes into your popups Nick List or popups Channel. Then you can right-click on your mirc's nick list or main chat screen to trigger the script.

You have two choices here, so you decide what you want.

That is all you need to do.

Originally Posted By: Tomao

Now you either type this command in your main mirc chat screen while inside your own chat room to voice those unvoiced people:

Code:

/m <Your Channel Name>

For example: /m #MyChat

Or

Code:

MassVoice:m $chan

<- This goes into your popups Nick List or popups Channel. Then you can right-click on your mirc's nick list or main chat screen to trigger the script.

You have two choices here, so you decide what you want.

That is all you need to do.

Thank you very much this has realy helped me! =]

Sorry for 'bumping' this old topic.

Is it possible to use this as, you select whom you want to voice
in the nicklist, and then make a rightclick menu saying ie. mv selected ?

Originally Posted By: starpossen

Sorry for 'bumping' this old topic.

Is it possible to use this as, you select whom you want to voice
in the nicklist, and then make a rightclick menu saying ie. mv selected ?

Code:

menu nicklist {
  $iif($me isop $active,Mass Voice) {
    var %x = $snick($active,0), %y = $active
    while (%x) { 
      var %r = %r $snick(%y,%x)
      if ($numtok(%r,32) = $modespl) { 
        mode %y + $+ $str(v,$modespl) %r
      } 
      dec %x
    }
    if (%r) { mode %y + $+ $str(v,$numtok(%r,32)) %r }
  }
}

You highlight and select the nicks you want to voice from the nicklist first, then right click to the popup menu, and tick "mass voice" to voice all of them.

Thanks alot for your reply, I will test it later.

~ Bump sorry, I have the Mass Voice added. I was wondering how I could get Mass De-Voice added with the Mass Voice.

Thanks

Code:

alias md {
  if $me !isop $1 { echo -a You are not OP in $1 | return }
  var %x = $nick($1,0,v) | while (%x) { 
    var %r = %r $nick($1,%x,v)
    if ($numtok(%r,32) = $modespl) { mode $1 - $+ $str(v,$modespl) %r | unset %r } 
    dec %x
  }
  if (%r) { mode $1 - $+ $str(v,$numtok(%r,32)) %r }
}

Usage: /md #channel