Creating new windows? - mIRC Discussion Forums

Hi, I'm trying to create a new window (@Notice) for all 'notices' to relay to. However, when I do this, ALL notices go to the same @Notice window, regardless of what network the notice was sent from. Here's the script I'm using now:

on ^*:NOTICE:*:* {
window -ael @Notice
aline @Notice ( $+ $nick $+ ): $1-
halt
}

Is there a way to tell remotes what network the notice is coming from, and have it open @Notice under the said network's tree? Also, is it possible to make the default font for this window "Arial"?

Thanks in advance for your support.

~Kevin

Okay, I fixed it myself. Here's what I came up with:

Code:

ON ^*:NOTICE:*:*: {  
  $iif(!$window($+(@Notices-,$network)),window -aelk0 $+(@Notices-,$network))
  aline $+(@Notices-,$network) 4( $+ $nick $+ ): $1- 
  beep
  halt 
}

Still, I need to create it with an Arial font.

(Just for support purposes) I got the font working correctly. Here's my final code:

Code:

ON ^*:NOTICE:*:*: {  
  $iif(!$window($+(@Notices-,$network)),window -g1ael $+(@Notices-,$network) Arial 12)
  aline $+(@Notices-,$network) $chr(3) $+ 04 $+ ( $+ $nick $+ ): $1- 
  beep
  halt 
}

How cool somebody posts a script when resolved

This will help everyone thanks

Yup, when someone finds the answer, they don't have to share but it helps others to benefit if they have similar issues. There have been a few people in the past who don't share the answer.

Okay, here's what you can do to get the window to change colors when a new notice arrives and the @Notice window isn't active:

Code:

ON ^*:NOTICE:*:*: {  
  $iif(!$window($+(@Notices-,$network)),window -ael $+(@Notices-,$network) Arial 12)
  aline $+(@Notices-,$network) 4( $+ $nick $+ ): $1- 
  window -g1 $+(@Notices-,$network)
  beep
  halt 
}

Notice the 'wingow -g1' line. Sorry I keep posting, but I think that every change that is made is vital to what people may want done.

How about adding:

Code:

 if ($ebeeps) beep

That way if $ebeeps are turned off (user choice) they won't hear those beeps.

Just a suggestion.

Originally Posted By: SladeKraven

How about adding:

Code:

 if ($ebeeps) beep

That way if $ebeeps are turned off (user choice) they won't hear those beeps.

Just a suggestion.

Not needed, /beep doen't work if $ebeeps = $false

Using aline -pi switches to to wrap and indent the text (and use the [c] parm to color it)
Also "if !$window()" in place of $iif(!...)

Code:

on ^*:notice:*:*:{
  if (!$window($+(@Notices-,$network))) { window -ael $+(@Notices-,$network) Arial 12 }
  aline -pi 4 $+(@Notices-,$network) ( $+ $nick $+ ): $1-
  window -g1 $+(@Notices-,$network)
  beep
  halt
}

Code:

on ^*:notice:*:*:{
  var %win = $+(@Notices-,$network)
  if (!$window(%win)) { window -ael %win Arial 12 }
  aline -pi 4 %win ( $+ $nick $+ ): $1-
  window -g1 %win
  beep
  halt
}

Neater, and doesn't have to evaluate $+() and $network so many times..

Just a query. Why use 'window -g1 ..' instead of 'aline -hpi ..' ?

Yeah, 'aline -h" is better again, thanks

Code:

on ^*:notice:*:*:{
  var %win = $+(@Notices-,$network)
  if (!$window(%win)) { window -ael %win Arial 12 }
  aline -hpi 4 %win ( $+ $nick $+ ): $1-
  beep
  halt
}

erm, that latest code doesn't wrap the text. I just tried it. Any ideas on that?

Ah. It's a listbox. (window -ael). List boxes don't wrap.

As it's just notices, there's no need for it to be a list box.

(Edit: Oops, forgot to preview!)

Getting rid of the 'listbox' makes the text start from the bottom of the @Notice window, and I'd like it to start from the top and move down. Any ideas there? Not sure that can be done, and I'll probably just have to get over it.