mIRC Homepage
Posted By: Krysis Noob Completely lost - 27/08/06 02:45 AM
Hi Im pretty new to this, but am slowly learning. the trouble is i need things now.... Probably i have them already but justd dont know how to access and change them.

1/ I need a way to be able to click on a nick. then be able to have a selection of replys available...I.E Nick Hello do you need help.
then maybe Click here for the link to the homepage
or similar replies
but i need to be able to add to or modify them.
......I believe the nick completer is similar but some of them seem to use fonts like white.andwe have a lot of chatspace types access us and they have white only...so unless i ctrl +k every time and i cant for the life of me find the place to change colors as a default blue or red..

2 Ban masks,, we would like to have a default list in numeric style ,,our ban mask list has a lot but based on the old stlye worded IPs and i read the asterix has to go else where...a list of 4 ranging from basic ban to relativly unbeatable would be nice..in numeric style. so we can click on nick and ban.

I do hope somone can help me and us out as we are trying to sop in some channels,,and have been dumped in at the deep end.

Thank you very much for your time
Posted By: FNar Re: Noob Completely lost - 27/08/06 04:43 AM
1) That's lame. If you can't take the trouble to type a reply, don't say anything. Color nick completers are also lame.

2) Read the FAQ - there's a list of all mask types.

Quote:
we are trying to sop in some channels, and have been dumped in at the deep end
Yell for a lifeguard (your channel's founder).
Posted By: Krysis Re: Noob Completely lost - 27/08/06 05:21 AM
Thank you for your constructive though some what lame reply...if this is the standard of help available well just as well i do give up on this project.....and the founder is more than pleased he has some people who are even willing to give up hours of free time to help..... But you obviously know better than him..

obviously in your odd little world you dont see the need to try and improve and simplify things,,, and as i said i have a list of masks and yes i have seen others on the web...i want them as numerical ones on my script.... and if you bothered to read you would have noticed i wasnt asking for a nick completer in colour and i also said there may be somthing that will do what i require already on the script....and if i had the time to learn all the stuff to script my own i would have done it....but to make that time id have to give up doing the things i need the scripts for.....and who else could we get to do it for me .....YOU??? i dont think so your not qualified in the subject andnot knowledgable enough to answer hardly any of the questions that we get.
Posted By: hixxy Re: Noob Completely lost - 27/08/06 05:52 AM
Code:
alias addreply { hadd -m replies $1 $$2- }
alias clearreplies { 
  if ($hget(replies)) { hfree $v1 }
}
alias isreply { return $iif($hget(replies,$1) != $null,$true,$false) }
alias removereply {
  if ($isreply($1)) { 
    hdel replies $1 
    if (!$hget(replies,0).item) { hfree replies }
  }
}
alias _ban {
  if ($istok(begin end,$1,32)) { return - }
  if ($1 isnum 1-20) { return Mask $1: ban $!chan $!1 $1 }
}
alias _replies {
  if ($istok(begin end,$1,32)) { return - }
  if ($hget(replies,$1).item) { return $replace($v1,% $+ 20,$chr(32)) $+ : msg $!1 $hget(replies,$v1) }
}

menu nicklist {
  Ban
  .$submenu($_ban($1))
}
menu nicklist,query {
  Replies
  .$submenu($_replies($1))
  .-
  .Add Reply:{
    var %reply = $replace($input(Enter name:,dei,Prompt),$chr(32),% $+ 20)
    if ($isreply(%reply)) { noop $input(That reply already exists,dho,Error) }
    else { addreply %reply $input(Enter text:,deo,Prompt) }
  }
  .Clear Replies:{
    if ($input(Are you sure you want to clear all replies?,devy,Prompt) == $yes) { clearreplies }
  }
  .Remove Reply:{
    var %reply = $replace($input(Enter name:,dei,Prompt),$chr(32),% $+ 20)
    if (!$isreply(%reply)) { noop $input(That reply doesn't exist,dho,Error) }
    else { removereply %reply }
  }
}

on *:exit:{
  if ($hget(replies)) { hsave -o $qt($scriptdir $+ replies.hsh) }
  else { .remove $qt($scriptdir $+ replies.hsh) }
}
on *:start:{
  if ($isfile($scriptdir $+ replies.hsh)) {
    if ($hget(replies)) { hfree $v1 }
    hmake replies 2
    hload replies $qt($scriptdir $+ replies.hsh)
  }
}


Right click on nicklist for ban options, right click on nicklist or in a query window for automated replies.

I didn't check if it saves the replies on exit and loads them on startup, but it should do. If it doesn't just post here.

Requires mIRC 6.17 or above.
Posted By: RusselB Re: Noob Completely lost - 27/08/06 06:44 AM
Please allow me to state that the level of response that you received from Fnar is far below the average that I'm used to seeing on this site, both in response to others from myself and other helpers, as well as in response to my own queries.

I see that hixxy has posted a response and I hope it works well for you. Per hixxy's response, if you have any problems, please don't hesitate to let us know.
Posted By: Krysis Re: Noob Completely lost - 28/08/06 06:38 AM
Thank you so much for your Quick resopnse and Posted script.. and thanks to RusselB for his response.

Whether i am doing somthing very wrong which is highly probable, But I seem to have a prob getting The script to even load... When i copy and Paste into remotes. the whole script changes to just 1 line. and no up scroll and after pressing ok No new things appear on R/click also it seemingly doesnt have saved into extras.

As I said im probably doing somthing wrong

Thank you again for your help and tollerance of a scripting deadhead
Posted By: RusselB Re: Noob Completely lost - 28/08/06 07:00 AM
This is a common problem encountered when using Internet Explorer to view these posts. The easy method to handle this, is to copy & paste into Notepad first, then from notepad to the script editor.

I used to have a link that would change the format of the posts so that it would copy properly but I've lost the link and I don't recall where on here I originally saw it. I did try to find it earlier using the search feature, but got far too many posts returned to go through them all.
Posted By: hixxy Re: Noob Completely lost - 28/08/06 12:51 PM
Notepad won't fix the formatting, but wordpad will.

You could also just quote the post and copy/paste it from the editbox.
Posted By: RusselB Re: Noob Completely lost - 28/08/06 09:17 PM
Ooops...wrong pad...I haven't had to worry about it for quite some time, as I use Firefox, which doesn't have that problem.
Posted By: hixxy Re: Noob Completely lost - 28/08/06 09:24 PM
Same here smile
© mIRC Discussion Forums