; _ ___ _ _ _ __ ______
; | |/ _ \| | _____ ___ ___ _ __(_)_ __ | |_ \ \/ / _ \
; _ | | | | | |/ / _ \/ __|/ __| '__| | '_ \| __| \ /| |_) |
; | |_| | |_| | < __/\__ \ (__| | | | |_) | |_ / \| __/
; \___/ \___/|_|\_\___||___/\___|_| |_| .__/ \__| /_/\_\_|
; |_|
; DALNET MODULE
;
#dalnet on
;Chanserv
on ^*:NOTICE:*:?:{
;echo $+(@C,$cid) $1-
if ($nick == $server) { echo $color(notice) -st $+([,$nick,], $1-) }
if ($nick == ChanServ) || ($nick == NickServ) || ($nick == MemoServ) {
if (!$window($+(@,$nick))) { window -Bemizvk[0] $+(@,$nick) }
if ($1) { echo -t $+(@,$nick) $+([,$target,]) $1- | titlebar $+(@,$nick) $target }
_hd
}
}
on *:INPUT:@*serv:{
$lower($left($remove($active,@),1) $+ s) $1-
}
menu *Nickserv {
$style(2) $server:{}
-
identify $window(@Nickserv).title:{ .ns IDENTIFY $$?*="Password:" }
register $window(@Nickserv).title:{ .ns REGISTER $$?*="Password:" $$?="@mail:" }
-
kill nick:{ .ns GHOST $$?="Enter nickname to ghost:" $$?*="Password:" }
-
drop nick?:{ .ns DROP $$?="Enter nickname to drop:" }
-
release nick:{ .ns RELEASE $$?="Enter nickname to release:" $$?*="Password:" }
}
menu *Chanserv {
$style(2) $server:{}
-
identify $chan:{ .cs identify $$?="Enter channel:" $$?*="Password:" }
register $chan:{ .cs register $$?="Enter channel:" $$?*="Password:" registered with J0kescript XP }
-
mass Kick/Ban:{ .cs mkick $$?="Enter channel:" }
mass Deop:{ .cs mdeop $$?="Enter channel:" }
-
# info:{ .cs info $$?="Enter channel:" }
}
menu *serv {
-
clear:{ cls }
}
alias /cs {
if (!$1) { echo -a ChanServ: Not enough parameters }
else { /.msg ChanServ $1- }
}
alias /csh /cs help $1-
alias /csl /cs $1 #$2 list
alias /csi /cs identify #$1 $2
alias /csub /cs unban #$1 $2-
alias /csin /cs invite #$1 $2-
;Chanserv specific
alias /csop /cs op #$1 $2-
alias /csdop /cs deop #$1 $2-
;NickServ
alias /ns {
if (!$1) { echo -a NickServ: Not enough parameters }
else { /.msg NickServ $1- }
}
alias /nsh /ns help $1-
alias /nsi /ns identify $1
;MemoServ
alias /ms {
if (!$1) { echo -a MemoServ: Not enough parameters }
else { /.msg MemoServ $1- }
}
alias /msh /ms help $1-
alias /msl /ms list $1-
alias /msdel /ms del $1-
;Specific
alias /dal { /mode #$1 + $+ $str($o,$modespl) $2- }
#dalnet end
