mIRC Home    About    Download    Register    News    Help

Print Thread
#230694 18/03/11 01:01 PM
Joined: Mar 2011
Posts: 5
W
Nutrimatic drinks dispenser
OP Offline
Nutrimatic drinks dispenser
W
Joined: Mar 2011
Posts: 5
Is there a way to see what happens in more than one channel in one window in mirc?

Joined: Aug 2004
Posts: 7,252
R
Hoopy frood
Offline
Hoopy frood
R
Joined: Aug 2004
Posts: 7,252
Technically, yes. You could write (or get written) a script that makes a custom window (/window) then captures the events (ACTION, NOTICE, TEXT) in the various channels, then puts the information into the custom window.

Personally, I think this could end up being very confusing, especially if you're on busy channels.

Joined: Mar 2011
Posts: 5
W
Nutrimatic drinks dispenser
OP Offline
Nutrimatic drinks dispenser
W
Joined: Mar 2011
Posts: 5
Some clients have it and i find it very helpful, but there is so many other things i luv about mirc so if I could get both of them I would be a happy man. Writing a script by my self agghh... it could be done, but it would be nice if there was something out there so I did not have to do anything by my self, you know lazyness...

Joined: Aug 2004
Posts: 7,252
R
Hoopy frood
Offline
Hoopy frood
R
Joined: Aug 2004
Posts: 7,252
There is the Scripting and Pop-Ups forum, though, technically, it's supposed to be a forum for helping with a script you have at least tried to write.

There's also a Snippet Request forum on Hawkee where you can request the snippet and have it done for you completely. Sometimes those requests take a few days, or longer, depending on the complexity of the request and the availability of a helper's time.

Joined: Sep 2005
Posts: 2,881
H
Hoopy frood
Offline
Hoopy frood
H
Joined: Sep 2005
Posts: 2,881
Code:
alias -l messagestyle { 
  if ($1 == text) { return $+(<,$chr(3),$cnick($nick).colour,$iif($chan && $left($nick($chan,$nick).pnick,1) isin $prefix,$v1),$nick,$chr(3),$colour(normal text),>) }
  elseif ($1 == action) { return * $nick }
  elseif ($1 == notice) { return $+(-,$chr(3),$cnick($nick).colour,$iif($chan && $left($nick($chan,$nick).pnick,1) isin $prefix,$v1),$nick,$chr(3),$colour(notice text),-) }
}
alias singlechannel { window $iif($window(@singlechannel),-a) @singlechannel }

on *:text:*:#:{
  if ($window(@singlechannel)) { echo -bcfilmrt "normal text" @singlechannel $chan -> $messagestyle($event) $1- }
}
on *:action:*:#:{
  if ($window(@singlechannel)) { echo -bcfilmrt "action text" @singlechannel $chan -> $messagestyle($event) $1- }
}
on *:notice:*:#:{
  if ($window(@singlechannel)) { echo -bcfilmrt "notice text" @singlechannel $chan -> $messagestyle($event) $1- }
}


Just type /singlechannel

Joined: Mar 2011
Posts: 5
W
Nutrimatic drinks dispenser
OP Offline
Nutrimatic drinks dispenser
W
Joined: Mar 2011
Posts: 5
Very,very nice, thanks!! It was something like this i was hoping for blush
And also a thanks to the rest of you guys.

Joined: Mar 2011
Posts: 5
W
Nutrimatic drinks dispenser
OP Offline
Nutrimatic drinks dispenser
W
Joined: Mar 2011
Posts: 5
hixxy:
This scrpit is so butiful, and well written it's almost make me cry. I don't know what more to say about this masterpiece of of scripting!

Joined: Sep 2005
Posts: 2,881
H
Hoopy frood
Offline
Hoopy frood
H
Joined: Sep 2005
Posts: 2,881
Haha no problem! smile

Joined: Jul 2007
Posts: 1,129
T
Hoopy frood
Offline
Hoopy frood
T
Joined: Jul 2007
Posts: 1,129
Could beautify it some more:
Code:
on *:text:*:#: sc
on *:action:*:#: sc
on *:notice:*:#: sc
alias -l sc {
  if ($window(@singlechannel)) { 
   echo -bcfilmrt $event @singlechannel $chan -> $messagestyle($event) $1- 
  }
}

Last edited by Tomao; 20/03/11 06:09 AM.
Joined: Mar 2011
Posts: 5
W
Nutrimatic drinks dispenser
OP Offline
Nutrimatic drinks dispenser
W
Joined: Mar 2011
Posts: 5
Thanks Tomao, but what would this do? I try to put it in the script but can't see any difference and don't have the ability to decipher what it means blush
One thing that would be nice, if, when I write in a channel window that it would come up in /singlechannel to. I really don't remember if it did that in the start when I first ran it?
But is a great lurker script, I can run when I am doing something else and still know what happen on my favourite channels wink

Joined: Sep 2005
Posts: 2,881
H
Hoopy frood
Offline
Hoopy frood
H
Joined: Sep 2005
Posts: 2,881
Code:
on *:input:#:{
  if (!$inpaste) && ((!$istok(/ $readini($mircini,text,commandchar),$left($1,1),32)) || ($ctrlenter)) {
    if ($window(@singlechannel)) { echo -bcfilmrt "own text" @singlechannel $+(<,$chr(3),$cnick($me).colour,$iif($left($nick($chan,$me).pnick,1) isin $prefix,$v1),$me,$chr(3),$colour(own text),>) $1- }
  }
}

Joined: Jul 2007
Posts: 1,129
T
Hoopy frood
Offline
Hoopy frood
T
Joined: Jul 2007
Posts: 1,129
Originally Posted By: wrigsted
Thanks Tomao, but what would this do? I try to put it in the script but can't see any difference and don't have the ability to decipher what it means blush
There's nothing to decipher really. What I did was basically consolidate hixxy's script and make it lighter with less bytes is all. I actually forgot to include the $1- in each event. :p I see hixxy has added the input event as per your request, and this is yet another consolidation:
Code:
on *:input:#: sc $1-
on *:text:*:#: sc $1-
on *:action:*:#: sc $1-
on *:notice:*:#: sc $1-
alias -l sc {
  if ($window(@singlechannel)) { 
    if ($istok(text action notice,$event,32)) {
      echo -bcfilmrt $event @singlechannel $chan -> $messagestyle($event) $1- 
      halt
    }
    if (!$inpaste) && ((!$istok(/ $readini($mircini,text,commandchar),$left($1,1),32)) || ($ctrlenter)) {
    echo -bcfilmrt own @singlechannel $chan -> $+(<,$chr(3),$cnick($me).colour,$iif($left($nick($chan,$me).pnick,1) isin $prefix,$v1),$me,$chr(3),$colour(own),>) $1- }
  }
}
alias -l messagestyle { 
  if ($1 == action) { return * $nick }
  elseif ($1 == text) { 
    return $+(<,$chr(3),$cnick($nick).colour,$iif($chan && $left($nick($chan,$nick).pnick,1) isin $prefix,$v1),$nick,$chr(3),$colour(normal),>) 
  }
  elseif ($1 == notice) { 
    return $+(-,$chr(3),$cnick($nick).colour,$iif($chan && $left($nick($chan,$nick).pnick,1) isin $prefix,$v1),$nick,$chr(3),$colour(notice),-) 
  }
}
alias singlechannel { window $iif($window(@singlechannel),-a) @singlechannel }


Link Copied to Clipboard