mIRC Home    About    Download    Register    News    Help

Topic Options
#222244 - 13/06/10 05:40 AM Lost all my scripts :(
Question Offline
Ameglian cow

Registered: 24/06/07
Posts: 40
Reinstalled windows and in the process lost all the scripts i had for IRC.

Main one i am looking for is to automatically identify my nick when i connect to a server. Anyone has any idea how to write that?

Top
#222245 - 13/06/10 05:45 AM Re: Lost all my scripts :( [Re: Question]
maconga Offline
Babel fish

Registered: 12/04/07
Posts: 60
I use this script. Might be a bit much for you. It's set to identify my name on the server, then connect me to the channels on that server after i have identified.

Save it, load it in the remote tab.

This script was created by " Riamus2 ", so give him the credit

Code:
alias setconnectinfo {

  set %login.enterthegame none
  set %channels.enterthegame #tastyspleen 

  set %login.freenode ns identify PASSWORD_HERE
  set %channels.freenode #ubuntu #windows

  set %login.cyanide-x ns identify PASSWORD_HERE
  set %channels.cyanide-x #masquerade #tripcat #nGen

  set %login.globalgamers ns identify PASSWORD_HERE
  set %channels.globalgamers #tastycast

  set %login.gamesurge ns identify PASSWORD_HERE
  set %channels.gamesurge #ql.tv #quakecon

  set %login.7-indonesia ns identify PASSWORD_HERE
  set %channels.7-indonesia #7-indonesia #help #facebook #english
}

ON 1:START:{
  setconnectinfo
  server irc.enterthegame.com 5555 -i NAME_HERE
  server -m irc.freenode.net 8001 -i NAME_HERE
  server -m irc.cyanide-x.net 6667 -i NAME_HERE
  server -m irc.globalgamers.net 6667 -i NAME_HERE
  server -m irc.gamesurge.net 6667 -i NAME_HERE
  server -m irc.7-indonesia.org 6666 -i NAME_HERE
}

on *:connect: {
  if ($($+(%,login.,$network),2) != None) { $v1 }
  else { join $($+(%,channels.,$network),2) }
}

on *:notice:*:?: {
  if ($nick == NickServ || $nick == Authserv) {
    if ((password accepted isin $1-) || (you are now identified isin $1-) || (recognize you isin $1-)) {    
      massjoin $($+(%,channels.,$network),2)
    }
  }
}

alias massjoin { 
  var %i = 1, %t = $numtok($1-,32) 
  while (%i <= %t) { 
    join $gettok($1-,%i,32) 
    inc %i 
  } 
}


Top
#222246 - 13/06/10 06:18 AM Re: Lost all my scripts :( [Re: Question]
argv0 Offline
Planetary brain

Registered: 13/10/03
Posts: 3918
Loc: Montreal, QC, Canada
Some networks allow you to put your nickserv password as the server password, freenode is one of them:

/server irc.freenode.net 6667 PASSWORD -i NICKNAME

The above will auth you with nickserv without a script (and yes, you can add it to your servers list this way too). Other networks might work the same way, otherwise use a similar script to the one provided above.
_________________________
- argv[0] on EFnet #mIRC
- "Life is a pointer to an integer without a cast"

Top
#223895 - 03/08/10 12:03 AM Re: Lost all my scripts :( [Re: maconga]
PaiSand Offline
Bowl of petunias

Registered: 02/08/10
Posts: 2
For GameSurge you use authserv
Is the same syntax but replace "ns identify PASSWORD_HERE
" for "authserv AUTH NAME_HERE PASSWORD_HERE"

At least on their site they ask to use that syntax. Apart from that all works perfectly.

By the way, thanks for the script, I love it.


Edited by PaiSand (03/08/10 12:08 AM)

Top
#223902 - 03/08/10 04:26 AM Re: Lost all my scripts :( [Re: PaiSand]
maconga Offline
Babel fish

Registered: 12/04/07
Posts: 60
Originally Posted By: PaiSand
For GameSurge you use authserv
Is the same syntax but replace "ns identify PASSWORD_HERE
" for "authserv AUTH NAME_HERE PASSWORD_HERE"

At least on their site they ask to use that syntax. Apart from that all works perfectly.

By the way, thanks for the script, I love it.


You don't have to replace anything for GameSurge, as I use " ns identify PASSWORD_HERE ". GameSurge, seems to use both. What you see In that script is what I use, and it works.

Top