Forums Scripts & Popups realy need help

; start offline timer to trigger "removeidlers"-alias every 30s
on *:start: .timerremoveidlers 0 30 removeidlers
on *:unload: .timerremoveidlers off

alias removeidlers {

  ; ######## SETUP START ########
  ; channels (separated by comma) 
  var %chans = #help,#anotherchannel
  ; max. idle duration (in seconds) 
  var %limit = 420
  ; kick delay (in milliseconds) 
  var %delay = 500
  ; ######## SETUP END ########

  ; create a clean temp file
  var %f = removeidlers.txt
  write -c $qt(%f)
  ; loop channels
  var %c = 1
  while ($gettok(%chans,%c,44)) {
    ; able to kick
    if ($me isop $v1) {
      ; loop users of that chan
      var %chan = $v2, %n = 1
      while ($nick(%chan,%n,r)) {
        var %nick = $v1
        ; if idle of that user exceeds idle limit: write kick command to temp file
        if ($nick(%chan,$v1).idle > %limit) { write $qt(%f) kick %chan %nick Please don't idle in %chan }
        inc %n
      }
    }
    inc %c
  }
  ; any lines in temp file
  if ($lines(%f)) { 
    ; play commands with specified delay to status window and remove tempfile
    .play -pcs $qt(%f) %delay 
    .remove $qt(%f)
  }
}

; text event triggering if you're op in that channel and stripped message is a single letter (A-z)
on $@*:text:/^[a-z]$/Si:#: {
  ; "item" = <server connection ID>.<channel name>.<nick>
  var %i = $+($cid,.,$chan,.,$nick)
  ; increase value of "item" in hash table "letterspam" (item auto-unsets after 30 seconds)
  hinc -mu30 letterspam %i 

  ; value of "item" is above 3 (4 or more letters had been spammed)
  if ($hget(letterspam,%i) > 3) {
    ; remove "item" from hash table "letterspam"
    hdel letterspam %i

    ; YOUR ACTION GOES HERE
    kick $chan $nick Don't spam single letters!

  }
}

on *:TEXT:!idle*:#uno: {
  var %limit = 60
  if (!$2) { msg $chan you must supply a nickname and optionally a channel. }
  else {
    if ((!$3) || (#$3 == $chan)) {
      if ($2 ison $chan) {
        var %idle = $nick($chan,$2).idle
        if (($me isop $chan) && ($2 != $me) && (%idle > %limit)) { kick $chan $2 You have been idle too long! ( $+ $duration(%idle) - limit is $duration(%limit) $+ ) }
        else { msg $chan $2 has been idle on $chan for $duration(%idle) $+ . }
      }
      else { msg $chan $2 is not on $chan $+ . }
    }
    elseif ($me ison #$3) {
      if ($2 ison #$3) { msg $chan $2 has been idle on #$3 for $duration($nick(#$3,$2).idle) $+ . }
      else { msg $chan $2 is not on #$3 $+ . }
    }
    else { msg $chan I am not on #$3 $+ . }
  }
}