Forums Scripts & Popups ircops

; who reply
RAW 352:*:{
  ; the user is on any channel (if you /who a channel, $2 will be this channel's name)
  if ($left($2,1) isincs $chantypes) {
    ; if the reply contains the *-char in "modes", and the "nick"-token does not match *serv
    if (* isin $7) && (*serv !iswm $6) {
      ; add this nick to a dynamic variable named "%ircops<connectionID><channel>"
      ; this variable will unset after 20 seconds or on mIRC exit
      set -eu20 $+(%,ircops,$cid,$2) $addtok( $($+(%,ircops,$cid,$2),2) ,$6,32)
    }
    haltdef
  }
}

; end of who
RAW 315:*:{
  ; you who'd a channel
  if ($left($2,1) isincs $chantypes) {
    ; echo to the channel window the content of the dynamic variable (or "none", if the variable has no content)
    echo $2 4,0Ircops $2 $+ : $iif( $($+(%,ircops,$cid,$2),2) ,$v1,none)
    unset $+(%,ircops,$cid,$2)
    haltdef
  }
}

menu channel {
  IRCOp-Scan 
  .$iif($timer($+(opersc,$cid,$chr(1),$chan)),$style(2)) Scan chan $chan now : {
    who $chan
    $+(.timeropersc,$cid,$chr(1),$chan) 1 25 opersc.off
  }
  .Set exclusions $chr(91) $numtok(%opersc.exclude,32) set $chr(93): {
    set %opersc.exclude $input(Nicks will be excluded from the output message if any mask in the following string $&
      matches the user's address. $crlf $crlf $+ Put masks in the format nick!user@host. $crlf $+ Separate multiple $&
      masks with a space.You may use wildcards (example: *serv!*@*).,eog,Set exclusions for IRCop-Scan,%opersc.exclude)
    opersc.maketable
  }
}

alias -l opersc.off { if ($hget($ctimer)) hfree $v1 }

alias -l opersc.maketable {
  var %n = 1
  if ($hget(opersc.exclude)) { hfree $v1 }
  while ($gettok(%opersc.exclude,%n,32)) {
    hadd -m opersc.exclude $v1
    inc %n
  }
}

on *:start: { opersc.maketable }

raw 352:*: {
  if ($timer($+(opersc,$cid,$chr(1),$2))) {
    haltdef
    if (* isin $7) {
      var %t = $+(opersc,$cid,$chr(1),$2)
      if ($hfind(opersc.exclude,$+($6,!,$3,@,$4),1,W)) { hinc -m %t excluded }
      else { hadd -m %t onicks $addtok($hget(%t,onicks),$6,32) }
    }
  }
}

raw 315:*: {
  if ($timer($+(opersc,$cid,$chr(1),$2))) {
    haltdef
    var %t = $timer($v1), %w = $gettok(%t,-1,1), %h = $sorttok($hget(%t,onicks),32), %n = $numtok(%h,32), %e = $hget(%t,excluded)
    ECHO $iif((%w ischan),$v1) * Found $iif((%n || %e),%n $iif(%e,$+([+,%e,])),no) $iif((%n != 1),users,user), with IRCOP-flag in %w $+ $iif(%h,:,.)
    $iif(%h,ECHO $iif((%w ischan),$v1) %h)
    .timer $+ %t -e
  }
}

on *:disconnect: {
  var %n = 1
  while ($timer(%n)) { $iif(($+(opersc,$cid,$chr(1),*) iswm $v1),timer $+ $v2 -e,inc %n) }
}

on *:unload: { 
  unset %opersc.exclude
  hfree -w opersc.*
}