Forums Scripts & Popups Best way to sort a bunch of data to return a list

alias filterexample {
  filter -ffcteu 2 32 infile.txt outfile.txt

  var %n = 1, %string
  while ($read(outfile.txt,n,%n) != $null) {
    %string = %string $gettok($v1,1,32)
    inc %n
  }
  ECHO -ag sorted string: %string
  ECHO -ag with commas: $replace(%string,$chr(32),$+($chr(44),$chr(32)))
}

alias test_scores {
  ; make the Scores table
  hmake Scores

  ; add values to the Scores hashtable
  hadd Scores Steve 100
  hadd Scores Bob 5
  hadd Scores Tim 800
  hadd Scores Cheeto 99

  ; save the Scores hashtable to a file
  hsave Scores Scores.file

  ; load the Scores hashtable (as a temporary table)
  hmake Scores_Temp
  hload Scores_Temp Scores.file

  ; sort the Scores hashtable
  hmake Scores_Sorted
  var %item, %data, %index, %count = $hget(Scores_Temp,0).item
  while (%count > 0) {
    ; step 1: get the lowest item
    %item = $hget(Scores_Temp,%count).item
    %data = $hget(Scores_Temp,%count).data
    %index = 1
    while (%index < %count) {
      if ($hget(Scores_Temp,%index).data < %data) {
        %item = $hget(Scores_Temp,%index).item
        %data = $hget(Scores_Temp,%index).data
      }
      inc %index
    }

    ; step 2: remove the item from the temp list
    hdel Scores_Temp %item

    ; step 3: add the item to the sorted list
    %index = sorted_ $+ $hget(Scores_Sorted,0).item
    hadd Scores_Sorted %index %item

    ; step 4: back to the beginning
    dec %count
  }
  
  ; get rid of the temp table
  hfree Scores_Temp

  echo -a - printing the items out, in their sorted order:
  %index = 0
  %count = $hget(Scores_Sorted,0).item
  while (%index < %count) {
    var %tmp = $hget(Scores_Sorted,sorted_ $+ %index)
    echo -a - %tmp has a score of $hget(Scores,%tmp)
    inc %index
  }

  echo -a - printing the items out, in their reverse sorted order:
  %index = $hget(Scores_Sorted,0).item
  while (%index > 0) {
    dec %index
    var %tmp = $hget(Scores_Sorted,sorted_ $+ %index)
    echo -a - %tmp has a score of $hget(Scores,%tmp)
  }
  
  ; get rid of the sorted table
  hfree Scores_Sorted
  
  ; get rid of the scores table
  hfree Scores
}