|
|
Joined: Apr 2007
Posts: 21
Ameglian cow
|
OP
Ameglian cow
Joined: Apr 2007
Posts: 21 |
I really need a +o+v alias so the channels i am op in I can talk to the other ops and voiced people. Like when i press F4 a box appear and i notice/msg to other Ops in the channel, and when press F5 a box appear i type the msg/channel and it goes to Ops+Voices in the channel rather than i type /notice @+#channel <msg>
Box appearance is must.
Please paste me the code and where to put in alias/remote.
WornBean
|
|
|
|
|
Joined: Dec 2008
Posts: 1,515
Hoopy frood
|
|
Hoopy frood
Joined: Dec 2008
Posts: 1,515 |
I did this i think this will be good, When you press F4 a box(window) appear and what ever you write into this box it's going into the Channel Oper(s).
alias opers {
if (($1) && ($1 ischan)) { set -e %ops_chan $$1 }
else { set -e %ops_chan $active }
if ($active ischan) { window -k0el16 @Ops- $+ %ops_chan 21 21 741 341 }
op_list
}
alias -l op_list {
var %c = 1
while ($nick(%ops_chan,%c,o)) {
aline -ln @Ops- $+ %ops_chan $+(@,$nick(%ops_chan,%c,o))
inc %c
}
}
on ^*:NOTICE:*:#: {
if (($target == $+(@,$chan)) && ($right($nick,4) !== Serv) && (*irc.com !iswm $nick) && (*irc.net !iswm $nick)) {
set -e %ops_chan $chan
if (!$window(@Ops- $+ %ops_chan)) { window -k0el16 @Ops- $+ %ops_chan 21 21 741 341 }
op_list
aline -hp $colour(notice) @Ops- $+ %ops_chan $+([,@,$nick,]) $1-
haltdef
}
}
on ^*:TEXT:*:#: {
if ($target == $+(@,$chan)) {
set -e %ops_chan $chan
if (!$window(@Ops- $+ %ops_chan)) { window -k0el16 @Ops- $+ %ops_chan 21 21 741 341 }
op_list
aline -hp $colour(notice) @Ops- $+ %ops_chan $+([,@,$nick,]) $1-
haltdef
}
}
on *:INPUT:*: {
if (($target == @Ops- $+ %ops_chan) && (/* !iswm $1-)) {
aline -hp $colour(notice) @Ops- $+ %ops_chan $+([,@,$nick,]) $1-
.onotice %ops_chan $1-
}
}
on *:CLOSE:@Ops-*: { unset %ops_chan }
on *:OP:#: {
if (($window(@Ops- $+ %ops_chan)) && ($chan == %ops_chan)) {
aline -ln @Ops- $+ %ops_chan $+(@,$opnick)
}
}
on *:DEOP:#: {
if (($window(@Ops- $+ %ops_chan)) && ($chan == %ops_chan)) {
dline -l @Ops- $+ %ops_chan $fline(@Ops- $+ %ops_chan,$+(@,$opnick),1,1)
}
}
on *:NICK: {
if ($window(@Ops- $+ %ops_chan) && ($newnick isop %ops_chan)) {
rline -l @Ops- $+ %ops_chan $fline(@Ops- $+ %ops_chan,$+(@,$nick),1,1) $+(@,$newnick)
}
}
on *:QUIT: {
if ($window(@Ops- $+ %ops_chan) && ($nick isop %ops_chan)) {
dline -l @Ops- $+ %ops_chan $fline(@Ops- $+ %ops_chan,$+(@,$nick),1,1)
}
}
on *:PART:#: {
if (($window(@Ops- $+ %ops_chan)) && ($chan == %ops_chan) && ($nick isop $chan)) {
dline -l @Ops- $+ %ops_chan $fline(@Ops- $+ %ops_chan,$+(@,$nick),1,1)
}
}
menu @Ops-* {
dclick: { query $remove($sline(@Ops- $+ %ops_chan,1),@) }
$iif($mouse.lb,Whois): { whois $$1 $$1 }
$iif($mouse.lb,DCC Allow): { dccallow + $+ $$1 }
-
$iif($mouse.lb,Ping): { ctcp $$1 ping }
$iif($mouse.lb,Time): { ctcp $$1 time }
$iif($mouse.lb,Version): { ctcp $$1 version }
$iif($mouse.lb,Send): { dcc send $$1 }
$iif($mouse.lb,Chat): { dcc chat $$1 }
$iif($mouse.lb,DNS): { dns $$1 }
$iif($mouse.lb,Userhost): { userhost $$1 }
}
alias f4 { opers }
Last edited by westor; 05/07/09 12:22 PM.
|
|
|
|
|
Joined: Apr 2007
Posts: 21
Ameglian cow
|
|
OP
Ameglian cow
Joined: Apr 2007
Posts: 21 |
its nice, but it cannot communicate with +v.
i want two options, 1. press F4 and open a window where only msg to +o,
2. press F5 where can msg to +v+o both.....
WornBean
|
|
|
|
|
Joined: Apr 2007
Posts: 21
Ameglian cow
|
|
OP
Ameglian cow
Joined: Apr 2007
Posts: 21 |
please post for both the options
Last edited by khurram_ch; 05/07/09 01:01 PM.
WornBean
|
|
|
|
|
Joined: Dec 2008
Posts: 1,515
Hoopy frood
|
|
Hoopy frood
Joined: Dec 2008
Posts: 1,515 |
Sorry i can't help you with that you want, i gave you only for op users
|
|
|
|
|
Joined: Aug 2004
Posts: 7,252
Hoopy frood
|
|
Hoopy frood
Joined: Aug 2004
Posts: 7,252 |
Not as sophisticated a code, but I think it meets your stated requirements. alias f4 {
var %msg = $$?="Enter message for Ops only to see here"
if ($me isop $chan) {
.onotice $chan For ops only: %msg
}
else {
var %a = 1
while %a <= $nick($chan,0,o) {
.timer -m 1 $calc(%a / 500) notice $nick($chan,%a,o) For ops only: %msg
inc %a
}
}
}
alias f5 {
var %msg = $$?="Enter message for Ops and Voiced to see here"
if ($me isop $chan) {
.onotice $chan For ops & voiced only: %msg
var %a = 1
while %a <= $nick($chan,0,v) {
.timer -m 1 $calc(%a / 500) notice $nick($chan,%a,v) For ops & voiced only: %msg
inc %a
}
}
else {
var %a = 1
while %a <= $nick($chan,0,ov) {
.timer -m 1 $calc(%a / 500) notice $nick($chan,%a,ov) For ops & voiced only: %msg
inc %a
}
}
}
Last edited by RusselB; 05/07/09 07:42 PM.
|
|
|
|
|
Joined: Apr 2007
Posts: 21
Ameglian cow
|
|
OP
Ameglian cow
Joined: Apr 2007
Posts: 21 |
hey RusselB
Pressing F4 works awesome this is what i need, it notices ops.
but there seems some prob in F5. (pressing F5 send notice to Ops and also send msg in query, and to voices it only send query msg(no notice) dear i dont want query msg, i want to send only notice both of them, like in F4.
WornBean
|
|
|
|
|
Joined: Apr 2007
Posts: 21
Ameglian cow
|
|
OP
Ameglian cow
Joined: Apr 2007
Posts: 21 |
thank you westor, you're really helping. i appreciate that.
WornBean
|
|
|
|
|
Joined: Aug 2004
Posts: 7,252
Hoopy frood
|
|
Hoopy frood
Joined: Aug 2004
Posts: 7,252 |
Neither of the codes I originally submitted sent notices, but the codes have been changed to do so.
I understand where the confusion is coming in, since the /omsg command acts similar to the /notice command, in that the information doesn't open a query box for the respective ops.
|
|
|
|
|
Joined: Apr 2007
Posts: 21
Ameglian cow
|
|
OP
Ameglian cow
Joined: Apr 2007
Posts: 21 |
RusselB its working now, but one last thing if you could do that, when press F5 it sends notice to both ops and voices, by pressing F4 it shows like @#channel, but by pressing F5 to ops it msg goes like @#channel rather than @+#channel, it also goes to voices but like a simple notice, for ops they think it is among ops only not voices and voices think this is an individual notice. is it possible that when we press F5 it shows @+#channel so everyone knows its amond ops and voices. thanks
WornBean
|
|
|
|
|
Joined: Aug 2004
Posts: 7,252
Hoopy frood
|
|
Hoopy frood
Joined: Aug 2004
Posts: 7,252 |
Quite simply, no, or at least not in the manner you are asking for. I will edit the code again (if I can) to handle your request to the best of my ability.
The @ character shows because it is a higher level of access than +, and the server (not mIRC), restricts the showing character to the one that is the highest level.
You will see this same thing in your nicklists if a nick has multiple modes assigned to them.
|
|
|
|
|
Joined: Aug 2004
Posts: 7,252
Hoopy frood
|
|
Hoopy frood
Joined: Aug 2004
Posts: 7,252 |
Per the additional information you supplied via pm, this should work as you want it. alias f4 {
var %msg = $$?="Enter message for Ops only to see here"
.notice $($+(@,$chan),2) %msg
}
alias f5 {
var %msg = $$?="Enter message for Ops only to see here"
.notice $($+(@+,$chan),2) %msg
}
This is untested, as I don't have an account on the network you specified in pm.
|
|
|
|
|
Joined: Apr 2007
Posts: 21
Ameglian cow
|
|
OP
Ameglian cow
Joined: Apr 2007
Posts: 21 |
this is perfect  thanks
WornBean
|
|
|
|
|
