mIRC Home    About    Download    Register    News    Help

Topic Options
#183862 - 23/08/07 06:11 AM Creating new windows?
OMGWTFItsKevin Offline
Nutrimatic drinks dispenser

Registered: 23/08/07
Posts: 7
Hi, I'm trying to create a new window (@Notice) for all 'notices' to relay to. However, when I do this, ALL notices go to the same @Notice window, regardless of what network the notice was sent from. Here's the script I'm using now:

on ^*:NOTICE:*:* {
window -ael @Notice
aline @Notice ( $+ $nick $+ ): $1-
halt
}

Is there a way to tell remotes what network the notice is coming from, and have it open @Notice under the said network's tree? Also, is it possible to make the default font for this window "Arial"?

Thanks in advance for your support.

~Kevin

Top
#183863 - 23/08/07 06:24 AM Re: Creating new windows? [Re: OMGWTFItsKevin]
OMGWTFItsKevin Offline
Nutrimatic drinks dispenser

Registered: 23/08/07
Posts: 7
Okay, I fixed it myself. Here's what I came up with:

Code:
ON ^*:NOTICE:*:*: {  
  $iif(!$window($+(@Notices-,$network)),window -aelk0 $+(@Notices-,$network))
  aline $+(@Notices-,$network) 4( $+ $nick $+ ): $1- 
  beep
  halt 
}


Still, I need to create it with an Arial font. crazy

Top
#183866 - 23/08/07 06:57 AM Re: Creating new windows? [Re: OMGWTFItsKevin]
OMGWTFItsKevin Offline
Nutrimatic drinks dispenser

Registered: 23/08/07
Posts: 7
(Just for support purposes) I got the font working correctly. Here's my final code:

Code:
ON ^*:NOTICE:*:*: {  
  $iif(!$window($+(@Notices-,$network)),window -g1ael $+(@Notices-,$network) Arial 12)
  aline $+(@Notices-,$network) $chr(3) $+ 04 $+ ( $+ $nick $+ ): $1- 
  beep
  halt 
}

Top
#183870 - 23/08/07 09:40 AM Re: Creating new windows? [Re: OMGWTFItsKevin]
piker Offline
Ameglian cow

Registered: 02/01/07
Posts: 31
How cool somebody posts a script when resolved smile This will help everyone thanks laugh

Top
#183873 - 23/08/07 10:33 AM Re: Creating new windows? [Re: piker]
SladeKraven Offline
Planetary brain

Registered: 19/12/02
Posts: 3547
Loc: Kent, England
Yup, when someone finds the answer, they don't have to share but it helps others to benefit if they have similar issues. There have been a few people in the past who don't share the answer.

Top
#183918 - 23/08/07 07:46 PM Re: Creating new windows? [Re: SladeKraven]
OMGWTFItsKevin Offline
Nutrimatic drinks dispenser

Registered: 23/08/07
Posts: 7
Okay, here's what you can do to get the window to change colors when a new notice arrives and the @Notice window isn't active:

Code:
ON ^*:NOTICE:*:*: {  
  $iif(!$window($+(@Notices-,$network)),window -ael $+(@Notices-,$network) Arial 12)
  aline $+(@Notices-,$network) 4( $+ $nick $+ ): $1- 
  window -g1 $+(@Notices-,$network)
  beep
  halt 
}


Notice the 'wingow -g1' line. Sorry I keep posting, but I think that every change that is made is vital to what people may want done.

Top
#183925 - 23/08/07 09:25 PM Re: Creating new windows? [Re: OMGWTFItsKevin]
SladeKraven Offline
Planetary brain

Registered: 19/12/02
Posts: 3547
Loc: Kent, England
How about adding:

Code:
 if ($ebeeps) beep


That way if $ebeeps are turned off (user choice) they won't hear those beeps.

Just a suggestion.

Top
#183929 - 23/08/07 10:10 PM Re: Creating new windows? [Re: SladeKraven]
deegee Offline
Fjord artisan

Registered: 16/06/06
Posts: 508
Loc: Storage
Originally Posted By: SladeKraven
How about adding:

Code:
 if ($ebeeps) beep


That way if $ebeeps are turned off (user choice) they won't hear those beeps.

Just a suggestion.

Not needed, /beep doen't work if $ebeeps = $false laugh

Top
#183930 - 23/08/07 10:16 PM Re: Creating new windows? [Re: OMGWTFItsKevin]
deegee Offline
Fjord artisan

Registered: 16/06/06
Posts: 508
Loc: Storage
Using aline -pi switches to to wrap and indent the text (and use the [c] parm to color it)
Also "if !$window()" in place of $iif(!...)
Code:
on ^*:notice:*:*:{
  if (!$window($+(@Notices-,$network))) { window -ael $+(@Notices-,$network) Arial 12 }
  aline -pi 4 $+(@Notices-,$network) ( $+ $nick $+ ): $1-
  window -g1 $+(@Notices-,$network)
  beep
  halt
}

Top
#183945 - 23/08/07 11:11 PM Re: Creating new windows? [Re: deegee]
Bekar Offline
Fjord artisan

Registered: 11/12/02
Posts: 503
Loc: Melbourne, Australia
Code:
on ^*:notice:*:*:{
  var %win = $+(@Notices-,$network)
  if (!$window(%win)) { window -ael %win Arial 12 }
  aline -pi 4 %win ( $+ $nick $+ ): $1-
  window -g1 %win
  beep
  halt
}

Neater, and doesn't have to evaluate $+() and $network so many times.. wink

Just a query. Why use 'window -g1 ..' instead of 'aline -hpi ..' ?

Top
#183948 - 23/08/07 11:20 PM Re: Creating new windows? [Re: Bekar]
deegee Offline
Fjord artisan

Registered: 16/06/06
Posts: 508
Loc: Storage

Yeah, 'aline -h" is better again, thanks laugh

Code:
on ^*:notice:*:*:{
  var %win = $+(@Notices-,$network)
  if (!$window(%win)) { window -ael %win Arial 12 }
  aline -hpi 4 %win ( $+ $nick $+ ): $1-
  beep
  halt
}

Top
#183972 - 24/08/07 04:04 AM Re: Creating new windows? [Re: deegee]
OMGWTFItsKevin Offline
Nutrimatic drinks dispenser

Registered: 23/08/07
Posts: 7
erm, that latest code doesn't wrap the text. I just tried it. Any ideas on that?

Top
#183995 - 24/08/07 11:31 AM Re: Creating new windows? [Re: OMGWTFItsKevin]
Bekar Offline
Fjord artisan

Registered: 11/12/02
Posts: 503
Loc: Melbourne, Australia
Ah. It's a listbox. (window -ael). List boxes don't wrap.

As it's just notices, there's no need for it to be a list box.

(Edit: Oops, forgot to preview!)


Edited by Bekar (24/08/07 11:31 AM)

Top
#184001 - 24/08/07 01:03 PM Re: Creating new windows? [Re: Bekar]
OMGWTFItsKevin Offline
Nutrimatic drinks dispenser

Registered: 23/08/07
Posts: 7
Getting rid of the 'listbox' makes the text start from the bottom of the @Notice window, and I'd like it to start from the top and move down. Any ideas there? Not sure that can be done, and I'll probably just have to get over it.

Top