Forums Bug Reports Strange /continue bug

; /rc <text> - Colors each character in a random color, but
; not the same one twice in a row. UTF-8 text is supported.
; Requires $utf8len().
rc {
  var %res, %spc, %lastcol
  var %len = $len($$1-), %i = 1

  while (%i <= %len) {
    var %chr = $mid($1-,%i,4)
    var %chrlen = $utf8len(%chr)
    %chr = $left(%chr, %chrlen)

    if (%chr == $chr(32)) {
      %spc = $true | inc %i | continue
    }

    var %col = %lastcol
    while (%col == %lastcol) %col = $rand(2,14)
    %lastcol = %col | if (%col < 10) %col = 0 $+ %col
    %col = $chr(3) $+ %col

    if (%spc) {
      %res = $+(%res,$chr(3)) $+(%col,%chr)
      %spc = $false
    }
    else %res = $+(%res,%col,%chr)

    inc %i %chrlen
  }

  say %res $+ $chr(3)
}


; $utf8len(buf) - Returns the size of the UTF-8 character
; started at the first byte of "buf". Only the first four
; bytes of "buf" make any difference. Returns 1 on error.
utf8len {
  if ($asc($1) < 128) return 1
  var %res = 1

  if (($v1 >= 194) && ($v1 <= 223)) %res = 2
  elseif (($v1 >= 224) && ($v1 <= 239)) %res = 3
  elseif (($v1 >= 240) && ($v1 <= 243)) %res = 4

  ; validate the other bytes
  var %i = 2
  while (%i <= %res) {
    if (($asc($mid($1,%i,1)) < 128) || ($v1 > 191)) {
      return 1
    }
    inc %i
  }

  return %res
}

alias conttest {
  var %len = 3
  var %i = 1

  while (%i <= %len) {
    echo -a IN
    if (%i == 2) {
      echo -a CONT
      inc %i
      continue
    }
    echo -a MID

    inc %i

    echo -a OUT
  }
}

IN
MID
OUT
IN
CONT
IN
MID
OUT

    echo -a MID
    var %n = 2
    while (%n) dec %n

IN
MID
OUT
IN
CONT

while (%n) dec %n

    while (%n) { dec %n } 

IN
MID
OUT
IN
CONT
OUT

    
while (%n) {
  dec %n 
} 

IN
MID
OUT
IN
CONT
IN
MID
OUT

; +++ CHANNELLIST / GET IRC STATS
; Input: $1 = network (optional)
; Output:
; $1 = total nets $2 = total chans $3 = total users
; $4 = amount Serve channels with USERDATA ON $5 = amount users on these channels
; $6 = amount of $4 with SCAN enabled $7 = amount users on these channels
; NOTE: do not put the level 3 loops on one line, it starts skipping last channel
alias SC_ChannelList_GetIRCStats {
  SC_dl SC_ChannelList_GetIRCStats $1-
  var %t = $SC_ts, %a = $asc(%t), %net = $1, %htotal = $SC_rh, %hud = $SC_rh, %hscan = $SC_rh, %4 = $chr(44)
  var %total1 = $scon(0), %i1 = 1, %totalnet = 0, %totalchan = 0, %totalchanud = 0, %totalchanscan = 0
  while (%i1 <= %total1) {
    var %neti = $hget(SC_H,$+(Server,%4,$scon(%i1).cid)) | if (%neti == $null) { inc %i1 | continue }
    if (%net != $null) && (%neti != %net) { inc %i1 | continue }
    scid $scon(%i1).cid | if ($status != connected) { inc %i1 | continue }
    inc %totalnet | var %total2 = $comchan($me,0), %i2 = 1
    while (%i2 <= %total2) {
      var %chan = $comchan($me,%i2) | tokenize %a $SC_ChannelList_Get(%neti,%chan,USERDATA,SCAN)
      if ($1 == NOTFOUND) { inc %i2 | continue }
      inc %totalchan | var %total3 = $nick(%chan,0), %i3 = 1
      while (%i3 <= %total3) {
        hadd %htotal $+(%neti,%t,$nick(%chan,%i3))
        inc %i3
      }
      if ($1 != ON) { inc %i2 | continue }
      inc %totalchanud | var %i3 = 1
      while (%i3 <= %total3) {
        hadd %hud $+(%neti,%t,$nick(%chan,%i3))
        inc %i3
      }
      if ($2 != ON) { inc %i2 | continue }
      inc %totalchanscan | var %i3 = 1
      while (%i3 <= %total3) { 
        hadd %hscan $+(%neti,%t,$nick(%chan,%i3))
        inc %i3 
      }
      inc %i2
    }
    inc %i1
  }
  var %user = $hget(%htotal,0).item, %userud = $hget(%hud,0).item, %userscan = $hget(%hscan,0).item
  hfree %htotal | hfree %hud | hfree %hscan | return %totalnet %totalchan %user %totalchanud %userud %totalchanscan %userscan
}

while (%i3 <= %total3) { hadd %htotal | $+(%neti,%t,$nick(%chan,%i3)) | inc %i3 }

while (%i3 <= %total3) {
 hadd %htotal $+(%neti,%t,$nick(%chan,%i3))
 inc %i3
}