Forums Scripts & Popups Socket Problems - HTTP POST

alias alta {
  sockopen alta world.altavista.com 80
}

on *:sockopen:alta:{
  if ($sockerr) return
  var %sw = sockwrite -tn $sockname
  var %data = doit=done&intl=1&tt=urltext&trtext=hello+this+is+a+really+long+message+hello+ $+ $&
    this+is+a+really+long+message+this+is+an+even+longer+message+so+lets+see+what+happens&lp=en_fr&btnTrTxt=Translate
  %sw POST /tr HTTP/1.1
  %sw Referer: http://world.altavista.com/tr
  %sw Content-Type: application/x-www-form-urlencoded
  %sw Host: world.altavista.com
  %sw Content-Length: $len(%data)
  %sw Connection: close
  %sw
  %sw %data
}

on *:sockread:alta:{
  if ($sockerr) return
  var %t
  sockread %t
  echo -s > %t
}

alias babel {
  if (!$1) {
    echo -a Syntax: /babel <words to translate here, max 700 chars>
    return
  }

  set %babel $left($1-,700)
  if ($sock(babel)) sockclose babel
  sockopen babel world.altavista.com 80
  if ($sockerr) babelfail
  .timerbabel 1 30 babelfail
}

alias babelfail {
  echo -a Error: Unable to connect to babelfish
  .timerbabel off
  unset %babel
  sockclose babel
}

on *:SOCKOPEN:babel:{
  if ($sockerr) {
    babelfail
    return
  }
  if (!%babel) {
    sockclose babel
    echo -a Error: No text to translate
    return
  }

  var %type = en_fr
  var %data = doit=done&intl=1&tt=urltext&trtext= $+ $replace(%babel,$chr(32),+) $+ &lp= $+ %type $+ &btnTrTxt=Translate
  var %write = sockwrite -tn $sockname

  %write POST /tr HTTP/1.1
  %write Referer: http://world.altavista.com/tr
  %write Content-Type: application/x-www-form-urlencoded
  %write Host: world.altavista.com
  %write Content-Length: $len(%data)
  %write Connection: close
  %write
  %write %data
}

on *:SOCKCLOSE:babel:{
  echo -s Error: Babelfish closed the connection
  .timerbabel off
  unset %babel
}

on *:SOCKREAD:babel:{
  var %sread
  sockread %sread

  var %regex = /<td bgcolor=white class=s><div style=padding:10px;>(.*)<\/div><\/td>/Si
  if ($regex(babel,%sread,%regex)) {
    echo -a " $+ %babel $+ " translates to " $+ $regml(babel,1) $+ "
    .timerbabel off
    unset %babel
    sockclose $sockname
  }
}

on *:SOCKREAD:babel:{
  var %sread
  sockread %sread

  if (%babelcontinue) %babelt = %babelt %sread

  var %regex = /<td bgcolor=white class=s><div style=padding:10px;>(.+)$/Si
  if ($regex(babel,%sread,%regex)) {
    set %babelt $regml(babel,1)
    set %babelcontinue 1
  }

  var %regex = /(.+)<\/div><\/td>/Si
  if ($regex(babelb,%babelt,%regex)) {
    set %babelt $regml(babelb,1)
    set %babelcontinue 0
    var %babeldone 1
  }

  if (%babeldone) {
    echo 4 -a " $+ %babel $+ " 
    echo 4 -a ...translates to...
    echo 4 -a " $+ %babelt $+ "
    .timerbabel off
    unset %babel*
    sockclose $sockname
  }
}