Forums Scripts & Popups Alias Scripting - whats wrong?

alias /idlemsg { 
  set %myidlezz $input(Enter In Idle Message,129)
  echo -a Idle Msg Set To: %myidlezz
  idlemsg on idlealias
  set %idlemsg on
}

alias /idlemsg {   
  set %myidlezz $$input(Enter In Idle Message,129) 
  echo -a Idle Msg Set To: %myidlezz  
  idlemsg on idlealias  
  set %idlemsg on
}

; –––––––––––––––––––––––––––––––––––––––––––––––+
; IdleScript v1.7                                |
; © 2005 by Forgotten (Justin)                   |
; Remember - ripping is lame                     |
; Visit www.pyro-studios.com                     |
; hellfire.redirectme.net 6667 #pyro             |
; –––––––––––––––––––––––––––––––––––––––––+–––––+
;  Special Thanks to SladeKraven (Andy)    |
; -----------------------------------------+


; ---------------
;  BEGIN REMOTES
; ---------------

on *:load:{
  echo -a ו•••••••••••••••••••••••••••••••••• ••••• ••• •• •• •• •  •
  echo -a IdleScript v1.7
  echo -a © 2005 by Forgotten (Justin)
  echo -a Visit www.pyro-studios.com
  echo -a hellfire.redirectme.net 6667 #pyro
  echo -a ו•••••••••••••••••••••••••••••••••• ••••• ••• •• •• •• •  •
  echo -a Read the commands.txt for commands or type !idle help
  echo -a ו•••••••••••••••••••••••••••••••••• ••••• ••• •• •• •• •  •
}
on 100:TEXT:!idle *:#: { 

  ; Basic Idle is turned on
  if ($2 == on) {
    if (%idlemsg == on) { msg $chan Already enabled. | halt }
    idlemsg on idlealias
    set %idlemsg on
    msg $chan Enabled.
  }

  ; Add User to DB
  if ($2 == add) {
    if ($3 == $null) { msg $chan Provide a user. | halt }
    guser 100 $3
    msg $chan Added user to database.
  }

  ; Define what an IdleBot is
  if ($2 == define) {
    msg $chan A IdleScript is an automatic program that will display a message after a given amount of time. It can be configured by msg, time, on, off, or winamp support.
  }

  ; WinAmp Idle or Basic Idle is turned off
  if ($2 == off) { 
    if (%idlemsg == off) {
      if (%idlewinamp == off) { msg $chan Already disabled. | halt }
      idlewinamp off
      set %idlewinamp off
      msg $chan WinAmp Idle Disabled.
      halt
    }
    idlemsg off
    set %idlemsg off
    msg $chan Disabled.
  }

  ; displays current config in channel
  if ($2 == state) {
    if (%idlewinamp == on) {
      msg $chan WinAmp Idle: on -=- Time Remaining: $duration($timer(idlemsg).secs) -=- Time Set: %myidletimer
      halt
    }
    msg $chan Idle State: %idlemsg -=- Time Remaining: $duration($timer(idlemsg).secs) -=- Time Set: %myidletimer
  }

  ; remotely sets time
  if ($2 == set) {
    if ($3 == $null) {
      msg $chan Provide a value
      halt
    }
    if ($4 == winamp) {
      set %myidletimer $3
      msg $chan Value set to: %myidletimer seconds for WinAmp Idle
      idlewinamp on
      halt
    }
    set %myidletimer $3
    msg $chan Value set to: %myidletimer seconds
    idlemsg on idlealias
    set %idlemsg on
  }

  ; remotely sets idle msg
  if ($2 == msg) {
    ; turns WinAmp Idle on or off (AMIP REQUIRED)
    if ($3 == winamp) {
      if (%idlewinamp == on) { msg $chan Already enabled. | halt }
      idlemsg off
      idlewinamp on
      msg $chan WinAmp Idle Enabled.
      halt
    }
    if ($3 == $null) {
      msg $chan Provide a message
      halt
    }
    msg $chan Value set to: $+(',$$3-,')
    set %myidlezz $$3-
  }

  ; displays msg in channel
  if ($2 == display) {
    idlealias
  }

  ; remotely sets channel
  if ($2 == chan) {
    if ($3 == $null) {
      msg $chan Provide a channel
      halt
    }
    set %myidlemsg2 $3
    msg $chan Channel: %myidlemsg2
  }

  ; messages user with commands
  if ($2 == help) {
    msg $nick 7,1[ !idle on: turns script on -=- !idle off: turns script off -=- !idle set <value>: sets time delay (in secs) -=- !idle state: displays info -=- !idle display: shows msg -=- !idle chan <channel>: set the channel the bot idles -=- !idle define: defines what the bot does -=- !idle add <username>: gives user access to commands ]
  }
}

; Basic Timer
alias idlemsg {
  if ($1 == on) { .timeridlemsg 0 %myidletimer $$2- }
  if ($1 == off) { .timeridlemsg off }
}

; WinAmp Timer
alias idlewinamp {
  if ($1 == on) { .timeridlemsg 0 %myidletimer /dde mplug announce }
  if ($1 == off) { .timeridlemsg off }
}

; Where the msg is assembled
alias idlealias {
  %myidlemsg %myidlemsg2 %myidlezz
}


; ---------------
;  BEGIN ALIASES
; ---------------

; displays the state
alias /idlestate { 
  echo -a ו•••••••••••••••••••••••••••••••••• ••••• ••• •• •• •• •  •
  echo -a Idle State: %idlemsg -=- Time Remaining: $duration($timer(idlemsg).secs) -=- Time Set: %myidletimer
  echo -a ו•••••••••••••••••••••••••••••••••• ••••• ••• •• •• •• •  •
}

; defines what a idlebot is
alias /idledefine {
  msg $chan A IdleScript is an automatic program that will display a message after a given amount of time. It can be configured by msg, time, on, off, or winamp support.
}

; turns script on
alias /idleon { 
  idlemsg on idlealias
  set %idlemsg on
  msg $chan Enabled.
}

; turns script off
alias /idleoff { 
  idlemsg off
  set %idlemsg off
  msg $chan Disabled.
}

; sets timer via field
alias /idleset { 
  set %myidletimer $input(Provide Wait Time. 1 = 1 second,129)
  echo -a Time Interval Set To: %myidletimer
  idlemsg on idlealias
  set %idlemsg on
}

; sets msg via field
alias /idlemsg { 
  set %myidlezz $input(Enter In Idle Message,129)
  echo -a Idle Msg Set To: %myidlezz
  idlemsg on idlealias
  set %idlemsg on
}

; sets channel via field
alias /idlechan {
  set %myidlemsg2 $input(Enter In Channel,129)
  msg $chan Channel: %myidlemsg2
}

; displays current msg
alias /idledisplay {
  echo -a %myidlezz
}

; turns WinAmp Idle on or off (AMIP REQUIRED)
alias /idlewa {
  if ($2 == on) {
    if (%idlewinamp == on) { if $chan { msg $chan Already enabled. } | halt }
    idlemsg off
    idlewinamp on
    echo -a WinAmp Idle Enabled.
    if $chan { msg $chan WinAmp Idle Enabled. }
  }
  if ($2 == off) {
    if (%idlewinamp == off) { if $chan { msg $chan Already disabled. } | halt }
    idlewinamp off
    set %idlewinamp off
    echo -a WinAmp Idle Disabled.
    if $chan { msg $chan WinAmp Idle Disabled. }
  }
}

; --------------------------------------
;  Special Thanks to SladeKraven (Andy)
; --------------------------------------

%myidletimer 600
%myidlemsg msg
%myidlemsg2 #CCCTown
%myidlezz 7,15 Tune in to Guru Radio at 15,7 http://216.12.162.147:7250/
%myidlewinamp /dde mplug announce
%idlemsg on
%idlewinamp off