On *:Start: {
hmake ulist
if ($isfile(ulist.hsh)) hload -i ulist ulist.hsh
}
menu menu,nicklist,status,channel,query {
$iif($dialog(ulist),$style(3)) User List: {
dialog -dm ulist ulist
}
}
dialog ulist {
title "User List"
size -1 -1 109 143
option dbu
combo 1, 4 4 102 107, size
button "Add", 2, 24 113 27 9
button "Rem", 3, 56 113 27 9
button "Close", 4, 37 127 37 12, ok
}
on *:dialog:ulist:sclick:2: {
if ($numtok($did($dname,1),32) > 1) {
if ($gettok($did($dname,1),1,32) == $gettok($did($dname,1),2,32)) {
echo -a Username and Password cannot be the same.
}
else {
if (!$hget(ulist,$gettok($did($dname,1),1,32))) {
hadd -m ulist $gettok($did($dname,1),1,32) $gettok($did($dname,1),2,32)
did -a ulist 1 $gettok($did($dname,1),1,32) $gettok($did($dname,1),2,32)
echo -a Success! - Added $+($chr(2),$gettok($did($dname,1),1,32),$chr(2)) with password $+($chr(2),$gettok($did($dname,1),2,32),$chr(2)) to User List.
halt
}
if ($hget(ulist,$gettok($did($dname,1),1,32))) {
echo -a $gettok($did($dname,1),1,32) already exists..
halt
}
}
}
else {
echo -a Add Users to list in the style of <User> <Password>
echo -a Example: Andy testpass123
}
}
On *:Dialog:ulist:sclick:3: {
if ($did($dname,1).sel) {
echo -a Success! - Deleted $gettok($did($dname,1).seltext,1,32)
hdel ulist $gettok($did($dname,1).seltext,1,32)
did -d ulist 1 $didwm(ulist,1,$did($dname,1).seltext,1)
}
}
On *:Dialog:ulist:init:0: {
var %x = 1
while (%x <= $hget(ulist,0).item) {
did -a ulist 1 $hget(ulist,%x).item $hget(ulist,%x).data
inc %x
}
}
On *:Dialog:ulist:close:0: {
hsave -i ulist ulist.hsh
}
On *:Text:login *:?: {
if ($hfind(ulist,$2) && $3 == $hget(ulist,$2)) {
msg $nick Username and password correct..
if ($me ison #ChannelHere) invite $nick $2
}
else {
msg $nick You need to specify your username and password to be invited..
}
}