I dont know of any event triggered when your send starts sending so, i wrote something on a timer....
ANYONE KNOW OF AN EVENT TO HOOK IN ON?
The 61 and 60 in the below alias is for a 60 second monitoring, if you want to increase it then increment that number up as needed.
;
;usage $start.watch.for.dcc.send(nick,filename,channel,message)
;usage !.echo -q $start.watch.for.dcc.send(nick,filename,channel,message)
;usage /start.watch.for.dcc.send nick filename channel message [ this option limited to filename having no spaces ]
;
alias start.watch.for.dcc.send {
var %timername = $+(WFDS.,$ticks,.,$rand(100001,199999))
set -u61 % $+ [ %timername ] $+ .nick $1
set -u61 % $+ [ %timername ] $+ .file $2
set -u61 % $+ [ %timername ] $+ .chan $3
set -u61 % $+ [ %timername ] $+ .mess $4-
.timer $+ %timername 60 1 watch.for.dcc.send %timername
}
;
alias -l watch.for.dcc.send {
var %nick = [ % $+ [ $1 $+ .nick ] ]
var %file = [ % $+ [ $1 $+ .file ] ]
var %i = $send(%nick,0)
while (%i) {
if (($send(%nick,%i).file == %file) && ($send(%nick,%i).status == active)) {
var %chan = [ % $+ [ $1 $+ .chan ] ]
var %mess = [ % $+ [ $1 $+ .mess ] ]
msg %chan %mess
.timer $+ $1 off
unset % $+ $1 $+ .*
halt
}
dec %i
}
}
That above is designed to be a routine u call when your doing a dcc send, it doesnt run on its own.
Directly precedding the dcc send (or directly following it) you need to do
$start.watch.for.dcc.send(nick,filename,channel,message)
* nick is the nick your sending the file to
* filename is the filename
* channel is the channel gfor your message (you can use a nick if u want)
* message is the message
so assuming your doing
/dcc send %nick %filename
then add to it to make....
/dcc send %nick %filename
$start.watch.for.dcc.send(%nick,%filename,#wombatworld,Master Wombat $me has started to send %filename to %nick so says the scrolls of wombatness)
above is a channel message or below is a private message
/dcc send %nick %filename
$start.watch.for.dcc.send(%nick,%filename,%nick,In case your completely blind in which case you wont see this anyway I am sedning you the file %filename now!)
*** limitations you cant have a comma in the message, u need to make it $chr(44) becuase the comma well seperate the parameters
*** The reason I dont call the alias using
/start.watch.for.dcc.send nick filename channel message is becuase the filename MAY have spaces in it, if it doesnt then you can use /start.watch.for.dcc.send