Disable join/part/quit msgs on specific channels

I was wondering, is there such an option for mIRC?

Paste this code into the 'Remotes' tab in the Script editor (alt+r), edit the #CHANNEL with your channel that you want to not display any join/part/quit message.

Code:

ON !^*:JOIN:#CHANNEL: { haltdef }
ON !^*:PART:#CHANNEL: { haltdef }
ON !^*:QUIT: {
  var %ch = #CHANNEL
  var %t = $chan(0)
  if (!%t) { return }
  var %i = 1
  while (%i <= %t) {
    var %c = $chan(%i)
    if (%c == %ch) && ($nick ison %c) { haltdef }
    elseif (%c !== %ch) && ($nick ison %c) { echo -tc quit %c * Quits: $nick ( $+ $iif($address($nick,10),$mid($v1,3-),N/A) $+ ) ( $+ $1- $+ ) }
    inc %i
  }
}

Thanks a bunch!

How should I add a 2nd channel?

Use this code if you want for multi-channels support:

Code:

ON !^*:JOIN:#CHANNEL,#CHANNEL2: { haltdef }
ON !^*:PART:#CHANNEL,#CHANNEL2: { haltdef }
ON !^*:QUIT: {
  var %ch = #CHANNEL,#CHANNEL2
  var %t = $chan(0)
  if (!%t) { return }
  var %i = 1
  while (%i <= %t) {
    var %c = $chan(%i)
    if ($istok(%ch,%c,44)) && ($nick ison %c) { haltdef }
    elseif (!$istok(%ch,%c,44)) && ($nick ison %c) { echo -tc quit %c * Quits: $nick ( $+ $iif($address($nick,10),$mid($v1,3-),N/A) $+ ) ( $+ $1- $+ ) }
    inc %i
  }
}

Just to shorten down and speed up the quit part:

Code:

on ^*:quit: {
  var %x = 1,%m $nick ( $+ $address $+ ) Quit ( $+ $iif($1-,$1-,Quit) $+ ),%c #channel1 #channel2
  while ($comchan($nick,%x)) {
    if (!$istok(%c,$v1,32)) echo $color(quit) -t $comchan($nick,%x) * %m
    inc %x
  }
  haltdef
}

Originally Posted By: level

I was wondering, is there such an option for mIRC?

Yes, mIRC supports this as a built-in feature. If you right-click on a channel's switchbar button, or click on its channel window icon in the top-left corner, or press alt - (alt+dash) from the channel, you will get a popup menu with an "Events..." menu entry. That entry opens a dialog with per-channel settings for all those events.

Wow, I'd give you an upvote if there were such a thing. Thank you so much!